DropNonUsableMaterialsServer()

void DropNonUsableMaterialsServer ( Man player, string part_name )

protected

См. определение в файле Construction.c строка 788

    {
        ConstructionPart construction_part = GetConstructionPart( part_name );
        
        string cfg_path = "cfgVehicles" + " " + GetParent().GetType() + " " + "Construction" + " " + construction_part.GetMainPartName() + " " + construction_part.GetPartName() + " " + "platform_support";
        string platform_support;
        
        if ( g_Game.ConfigIsExisting( cfg_path ) )
        {       
            g_Game.ConfigGetText( cfg_path, platform_support );
        }
        
        if ( platform_support.Length() > 0 || construction_part.IsBase() )
        {
            string at_cfg_path = "cfgVehicles" + " " + GetParent().GetType() + " "+ "GUIInventoryAttachmentsProps";
            
            if ( g_Game.ConfigIsExisting( at_cfg_path ) )
            {
                int child_count = g_Game.ConfigGetChildrenCount( at_cfg_path );
                
                for ( int i = 0; i < child_count; i++ )
                {
                    string child_name;
                    g_Game.ConfigGetChildName( at_cfg_path, i, child_name );
                    child_name.ToLower();
                    
                    if ( child_name.Contains( platform_support ) )
                    {
                        ref array<string> attachment_slots = new array<string>;
                        g_Game.ConfigGetTextArray( at_cfg_path + " " + child_name + " " + "attachmentSlots", attachment_slots );
                        
                        for ( int j = 0; j < attachment_slots.Count(); ++j )
                        {
                            //get material
                            ItemBase attachment = ItemBase.Cast( GetParent().FindAttachmentBySlotName( attachment_slots.Get( j ) ) );
                            
                            //material still attached
                            if ( attachment )
                            {
                                InventoryLocation inventory_location = new InventoryLocation;
                                attachment.GetInventory().GetCurrentInventoryLocation( inventory_location );
                                if (LogManager.IsBaseBuildingLogEnable()) bsbDebugPrint("[bsb] " + Object.GetDebugName(GetParent()) + " DropNonUsableMaterials UNlocking slot=" + inventory_location.GetSlot());
                                
                                //unlock slot
                                GetParent().GetInventory().SetSlotLock( inventory_location.GetSlot() , false );
                                
                                EntityAI parent = GetParent();
                                if (!parent)
                                    parent = player;
                                
                                int quantity_max = attachment.GetTargetQuantityMax(-1);
                                InventoryLocation dst = new InventoryLocation;
                                vector mat[4];
                                attachment.GetTransform(mat);
                                //TODO: why are we spawning and deleting here, instead of moving to location??
                                if ( parent.MemoryPointExists("" + part_name + "_materials") )
                                {
                                    vector destination = parent.GetMemoryPointPos("" + part_name + "_materials");
                                    destination = g_Game.ObjectModelToWorld(parent,destination);
                                    float health = attachment.GetHealth("","Health");
                                    float quantity = attachment.GetQuantity() - 1;
                                    if (quantity < 1.0)
                                        quantity = 1.0;
                                    float dir[4];
                                    inventory_location.GetDir(dir);
                                    dst.SetGroundEx(attachment,destination,dir);
                                    
                                    if (player)
                                    {
                                        vector posHead;
                                        MiscGameplayFunctions.GetHeadBonePos(PlayerBase.Cast(player),posHead);
                                        MiscGameplayFunctions.CreateItemBasePilesDispersed(attachment.GetType(),posHead,destination,UAItemsSpreadRadius.NARROW,quantity,health,player);
                                    }
                                    else
                                    {
                                        MiscGameplayFunctions.CreateItemBasePiles(attachment.GetType(),destination,quantity,health,true);
                                    }
                                    attachment.AddQuantity( -quantity );
                                }
                                else
                                {
                                    dst.SetGround(attachment,mat);
                                    
                                    for ( int k = attachment.GetQuantity(); k > quantity_max;  )
                                    {
                                        Object o = parent.GetInventory().LocationCreateEntity( dst, attachment.GetType(), ECE_PLACE_ON_SURFACE, RF_DEFAULT );
                                        ItemBase new_item = ItemBase.Cast( o );
                                        
                                        if( new_item )
                                        {
                                            MiscGameplayFunctions.TransferItemProperties( attachment, new_item );
                                            attachment.AddQuantity( -quantity_max );
                                            new_item.SetQuantity( quantity_max );
                                        }
                                        k -= quantity_max;
                                    }
                                }
                                
                                //drop
                                if (attachment.GetQuantity() > 0)
                                {
                                    if ( g_Game.IsMultiplayer() )
                                    {
                                        parent.ServerTakeToDst( inventory_location, dst );
                                    }
                                    else
                                    {
                                        parent.LocalTakeToDst( inventory_location, dst );
                                    }
                                }
                                else
                                {
                                    attachment.Delete();
                                }
                            }
                        }
                    }
                }
            }
        }
    }

Перекрестные ссылки bsbDebugPrint(), string::Contains(), ECE_PLACE_ON_SURFACE, g_Game, GetConstructionPart(), InventoryLocation::GetDir(), ConstructionPart::GetMainPartName(), GetParent(), ConstructionPart::GetPartName(), InventoryLocation::GetSlot(), ConstructionPart::IsBase(), LogManager::IsBaseBuildingLogEnable(), string::Length(), EntityAI::LocalTakeToDst(), UAItemsSpreadRadius::NARROW, RF_DEFAULT, EntityAI::ServerTakeToDst(), InventoryLocation::SetGround(), InventoryLocation::SetGroundEx(), ItemBase::SetQuantity() и string::ToLower().

Используется в DestroyPartServer() и DismantlePartServer().