OnEvent() [1/2]

override void CGame::OnEvent ( EventType eventTypeId, Param params )

inlineprivate

См. определение в файле DayZGame.c строка 1433

    {
        string address;
        int port;
        int high, low;
        
        switch (eventTypeId)
        {
            case StartupEventTypeID:
            {
                #ifndef SERVER
                // Just call it, to create the global instance if it doesn't exist yet
                ParticleManager.GetInstance();
                #endif
                break;
            }
            case MPSessionStartEventTypeID:
            {
                #ifndef SERVER
                ClearConnectivityStates();
                #endif
                m_FirstConnect = true;
                ClientData.ResetClientData();
                break;
            }
            case MPSessionEndEventTypeID:
            {
                LoadingHide();
                CancelLoginTimeCountdown();
                SetConnecting(false);
                SetGameState(DayZGameState.MAIN_MENU);
                m_FirstConnect = true;
                #ifdef PLATFORM_CONSOLE
                if (GetUserManager().GetSelectedUser())
                {
                    OnlineServices.LeaveGameplaySession();
                    OnlineServices.ClearCurrentServerInfo();
                    if (GetGameState() == DayZGameState.IN_GAME)
                    {
                        SetLoadState(DayZLoadState.MAIN_MENU_START);
                    }
                }
                m_Notifications.ClearVoiceNotifications();
                #endif
 
                // analytics - disconnected player
                StatsEventDisconnectedData discData = new StatsEventDisconnectedData();
                discData.m_CharacterId = g_Game.GetDatabaseID();
                discData.m_Reason = "quit";
                Analytics.PlayerDisconnected(discData);
                break;
            }
            case MPSessionFailEventTypeID:
            {
                CancelLoginQueue();
                LoadingHide(true);
                SetConnecting(false);
                ProgressAsync.DestroyAllPendingProgresses();
                
                if (GetGameState() == DayZGameState.CONNECTING)
                {
                    SetGameState(DayZGameState.MAIN_MENU);
                }
                
                break;
            }
            case MPSessionPlayerReadyEventTypeID:
            {
                LoadingHide(true);
                ProgressAsync.DestroyAllPendingProgresses();
                
                SetGameState(DayZGameState.IN_GAME);
                
                // analytics - spawned
                StatsEventSpawnedData spawnData = new StatsEventSpawnedData();
                spawnData.m_CharacterId = g_Game.GetDatabaseID();
                spawnData.m_Lifetime = 0;
                spawnData.m_Position = vector.Zero;
                if (GetPlayer())
                {
                    spawnData.m_Position = GetPlayer().GetPosition();
                }
                spawnData.m_DaytimeHour = 0;
                spawnData.m_Population = 0;
                Analytics.PlayerSpawned(spawnData);
                
                #ifdef PLATFORM_CONSOLE
                m_Notifications.ClearVoiceNotifications();
                OnlineServices.SetMultiplayState(true);
                #endif
                if (m_FirstConnect)
                {
                    m_FirstConnect = false;
                    if (GetHostAddress(address, port))
                    {
                        AddVisitedServer(address, port);
                    }
                    
                    #ifdef PLATFORM_CONSOLE
                        #ifndef PLATFORM_WINDOWS // if app is not on Windows with -XBOX parameter
                            if (null != GetUserManager().GetSelectedUser())
                            {
                                OnlineServices.EnterGameplaySession();
                                OnlineServices.LoadVoicePrivilege();
                            }
                        #endif
                    #endif
                }
                
                UpdateInputDeviceDisconnectWarning();
                
                break;
            }
            case MPConnectionLostEventTypeID:
            {
                MPConnectionLostEventParams conLost_params;
                if (Class.CastTo(conLost_params, params))
                {
                    int duration = conLost_params.param1;
                    OnMPConnectionLostEvent(duration);
                }
                break;
            }
            case WorldCleaupEventTypeID:
            {
                LoadingShow();
                break;
            }
            case DialogQueuedEventTypeID:
            {
                GetCallQueue(CALL_CATEGORY_SYSTEM).Call(g_Game.CheckDialogs);
                break;
            }
            case ChatMessageEventTypeID:
            {
                ChatMessageEventParams chat_params;
                if (Class.CastTo(chat_params, params))
                {
                    
                }
                break;
            }
            case ProgressEventTypeID:
            {
                ProgressEventParams prog_params;
                if (Class.CastTo(prog_params, params))
                    LoadProgressUpdate(prog_params.param1, prog_params.param2, prog_params.param3);
                break;
            }
            case LoginTimeEventTypeID:
            {
                LoginTimeEventParams loginTimeParams;
                if (Class.CastTo(loginTimeParams, params))
                {
                    OnLoginTimeEvent(loginTimeParams.param1);
                }
                break;
            }   
            case RespawnEventTypeID:
            {
                RespawnEventParams respawnParams;
                if (Class.CastTo(respawnParams, params))
                {
                    OnRespawnEvent(respawnParams.param1);
                }   
                break;
            }
            case PreloadEventTypeID:
            {
                PreloadEventParams preloadParams;
                if (Class.CastTo(preloadParams, params))
                {
                    OnPreloadEvent(preloadParams.param1);
                }   
                break;
            }
            case LogoutEventTypeID:
            {
                LogoutEventParams logoutParams;
                if (Class.CastTo(logoutParams, params))
                {
                    GetCallQueue(CALL_CATEGORY_GUI).Call(GetMission().StartLogoutMenu, logoutParams.param1);                     
                }
                break;
            }
            case SelectedUserChangedEventTypeID:
            {
                OnlineServices.Init();
                break;
            }
            case LoginStatusEventTypeID:
            {
                LoginStatusEventParams loginStatusParams;
                Class.CastTo(loginStatusParams, params);
    
                string msg1 = loginStatusParams.param1;
                string msg2 = loginStatusParams.param2;
                string finalMsg;
                    
                // write either to login time screen or loading screen
                if (m_LoginTimeScreen)
                {
                    finalMsg = msg1;
                    // login time screen supports two lines
                    if (msg2.Length() > 0)
                        finalMsg += "\n" + msg2;
                        
                    m_LoginTimeScreen.SetStatus(finalMsg);
                }
                else if (m_loading)
                {
                    // loading only one line, but it's a long one
                    finalMsg = msg1 + " " + msg2;
                    m_loading.SetStatus(finalMsg);
                }
                break;
            }
            case ConnectingStartEventTypeID:
            {
                g_Game.SetGameState(DayZGameState.CONNECTING);
                SetConnecting(true);
                break;
            }
            case ConnectingAbortEventTypeID:
            {
                g_Game.SetGameState(DayZGameState.MAIN_MENU);
                SetConnecting(false);
                if (m_ConnectFromJoin)
                {
                    m_ConnectFromJoin = false;
                    AbortMission();
                }
                break;
            }
            case DLCOwnerShipFailedEventTypeID:
            {
                DLCOwnerShipFailedParams dlcParams;
                if (Class.CastTo(dlcParams, params))
                {
                    Print("### DLC Ownership failed !!! Map: " + dlcParams.param1);
                }
                break;
            }
            case ConnectivityStatsUpdatedEventTypeID:
            {
                ConnectivityStatsUpdatedEventParams connectivityStatsParams; 
                if (Class.CastTo(connectivityStatsParams, params))
                {
                    PlayerIdentity playerIdentity = connectivityStatsParams.param1;
                    
                    int pingAvg = playerIdentity.GetPingAvg();
                    if (pingAvg < GetWorld().GetPingWarningThreshold())
                    {
                        SetConnectivityStatState(EConnectivityStatType.PING, EConnectivityStatLevel.OFF);
                    }
                    else if (pingAvg < GetWorld().GetPingCriticalThreshold())
                    {
                        SetConnectivityStatState(EConnectivityStatType.PING, EConnectivityStatLevel.LEVEL1);
                    }
                    else
                    {
                        SetConnectivityStatState(EConnectivityStatType.PING, EConnectivityStatLevel.LEVEL2);
                    }
                }
                break;
            }
            case ServerFpsStatsUpdatedEventTypeID:
            {
                ServerFpsStatsUpdatedEventParams serverFpsStatsParams; 
                if (Class.CastTo(serverFpsStatsParams, params))
                {
                    #ifdef DIAG_DEVELOPER
                    m_ServerFpsStatsParams = serverFpsStatsParams;
                    #endif
                    float fps = serverFpsStatsParams.param1;
                    if (fps > GetWorld().GetServerFpsWarningThreshold())
                    {
                        SetConnectivityStatState(EConnectivityStatType.SERVER_PERF, EConnectivityStatLevel.OFF);
                    }
                    else if (fps > GetWorld().GetServerFpsCriticalThreshold())
                    {
                        SetConnectivityStatState(EConnectivityStatType.SERVER_PERF, EConnectivityStatLevel.LEVEL1);
                    }
                    else
                    {
                        SetConnectivityStatState(EConnectivityStatType.SERVER_PERF, EConnectivityStatLevel.LEVEL2);
                    }
                }
                break;
            }
        }
        
        VONManager.GetInstance().OnEvent(eventTypeId, params);
 
        Mission mission = GetMission();
        if (mission)
        {
            mission.OnEvent(eventTypeId, params);
        }
        
        ErrorModuleHandler emh = ErrorModuleHandler.GetInstance();
        if (emh)
            emh.OnEvent(eventTypeId, params);
    }

Перекрестные ссылки AbortMission(), AddVisitedServer(), ScriptCallQueue::Call(), CALL_CATEGORY_GUI, CALL_CATEGORY_SYSTEM, CancelLoginQueue(), CancelLoginTimeCountdown(), Class::CastTo(), ChatMessageEventTypeID, ClearConnectivityStates(), OnlineServices::ClearCurrentServerInfo(), ConnectingAbortEventTypeID, ConnectingStartEventTypeID, ConnectivityStatsUpdatedEventTypeID, ProgressAsync::DestroyAllPendingProgresses(), DialogQueuedEventTypeID, DLCOwnerShipFailedEventTypeID, OnlineServices::EnterGameplaySession(), g_Game, GetCallQueue(), GetGameState(), GetHostAddress(), ErrorModuleHandler::GetInstance(), VONManager::GetInstance(), GetMission(), PlayerIdentityBase::GetPingAvg(), GetPlayer(), GetUserManager(), GetWorld(), OnlineServices::Init(), OnlineServices::LeaveGameplaySession(), string::Length(), LoadingHide(), LoadingShow(), LoadProgressUpdate(), OnlineServices::LoadVoicePrivilege(), LoginStatusEventTypeID, LoginTimeEventTypeID, LogoutEventTypeID, StatsEventDisconnectedData::m_CharacterId, StatsEventSpawnedData::m_CharacterId, m_ConnectFromJoin, StatsEventSpawnedData::m_DaytimeHour, m_FirstConnect, StatsEventSpawnedData::m_Lifetime, m_loading, m_LoginTimeScreen, m_Notifications, StatsEventSpawnedData::m_Population, StatsEventSpawnedData::m_Position, StatsEventDisconnectedData::m_Reason, mission, MPConnectionLostEventTypeID, MPSessionEndEventTypeID, MPSessionFailEventTypeID, MPSessionPlayerReadyEventTypeID, MPSessionStartEventTypeID, ErrorModuleHandler::OnEvent(), VONManagerBase::OnEvent(), OnLoginTimeEvent(), OnMPConnectionLostEvent(), OnPreloadEvent(), OnRespawnEvent(), ParticleManager(), Analytics::PlayerDisconnected(), Analytics::PlayerSpawned(), PreloadEventTypeID, Print(), ProgressEventTypeID, ClientData::ResetClientData(), RespawnEventTypeID, SelectedUserChangedEventTypeID, ServerFpsStatsUpdatedEventTypeID, SetConnecting(), SetConnectivityStatState(), SetGameState(), SetLoadState(), OnlineServices::SetMultiplayState(), StartupEventTypeID, UpdateInputDeviceDisconnectWarning(), WorldCleaupEventTypeID и vector::Zero.