Update()

void Update ( float deltaT )

protected

См. определение в файле EmoteManager.c строка 299

    {
        // no updates on restrained characters
        if (m_Player.IsRestrained())
            return;
        
        if (m_ItemToBeCreated)
        {
            if (g_Game.IsServer() && m_Callback && !m_Player.GetItemInHands())
            {
                m_Player.GetHumanInventory().CreateInHands("SurrenderDummyItem");
            }
            m_ItemToBeCreated = false;
        }
        
        int gestureSlot = 0;
        #ifndef SERVER
            gestureSlot = DetermineGestureIndex();
        #endif
        
        //nuclear solution to inventory question
        if (g_Game.IsClient() && g_Game.GetUIManager().FindMenu(MENU_INVENTORY) && IsEmotePlaying())
            m_Player.CloseInventoryMenu();
        
        //deferred emote cancel
        if (m_InstantCancelEmote) //'hard' cancel
        {
            if (m_Callback)
                m_Callback.Cancel();
            
            ClearEmoteLauncher();
            ClearDeferredExecution();
            m_InstantCancelEmote = false;
            SetPending(false);
            
            if (m_IsSurrendered)
                ClearSurrenderState();
            else
                SetEmoteLockState(false);
        }
        else if (m_CancelEmote) //'soft' cancel
        {
            SetPending(false);
            m_CancelEmote = false;
            
            if (m_IsSurrendered)
                ClearSurrenderState();
            else if (m_Callback)
                m_Callback.InternalCommand(DayZPlayerConstants.CMD_ACTIONINT_INTERRUPT);
        }
        
        if (m_DeferredEmoteLauncherCleanup)
        {
            ClearEmoteLauncher(true);
            m_DeferredEmoteLauncherCleanup = false;
        }
        
        //if (m_DisconnectEmoteQueued && (!m_bEmoteIsPlaying && !m_bEmoteIsRequestPending))
        if (m_DisconnectEmoteQueued)
        {
            if (!m_MenuEmote || !m_MenuEmote.IsStartGuaranteed())
            {
                CreateEmoteCBFromMenu(EmoteConstants.ID_EMOTE_SITA);
                m_MenuEmote.SetForced(EmoteLauncher.FORCE_DIFFERENT);
                m_MenuEmote.SetStartGuaranteed(true);
                
                EmoteBase emote = EmoteBase.Cast(m_NameEmoteMap.Get(m_MenuEmote.GetID()));
                int stanceIdx = DayZPlayerUtils.ConvertStanceMaskToStanceIdx(emote.GetStanceMaskFullbody());
            
                //if the emote cannot be played, don't sent a request to server
                if (!DayZPlayerUtils.PlayerCanChangeStance(m_Player, stanceIdx))
                {
                    m_MenuEmote = null; //setting this to null also ensures that the forcedEmotQueuedClient below is also false
                    m_DisconnectEmoteQueued = false;
                }
            }
        }
        
        bool forcedEmoteQueuedClient = m_MenuEmote && !m_MenuEmote.WasSynced() && m_MenuEmote.GetForced() > EmoteLauncher.FORCE_NONE && !g_Game.IsDedicatedServer();
        if (forcedEmoteQueuedClient) //regular forced emote playing
        {
            SendEmoteRequestSyncEx(m_MenuEmote);
        }
        else if (m_Callback)
        {
            bool uiGesture = false;
            if (!g_Game.IsDedicatedServer())
            {
                uiGesture = g_Game.GetUIManager().IsMenuOpen(MENU_GESTURES);
                
                if (InterruptGestureCheck())
                {
                    SendEmoteRequestSync(CALLBACK_CMD_END);
                }
                
                if (InterruptWaterCheck())
                {
                    SendEmoteRequestSync(CALLBACK_CMD_INSTACANCEL);
                }
            }
            
            if (gestureSlot > 0 || m_GestureInterruptInput || (m_HIC.IsSingleUse() && !uiGesture) || (m_HIC.IsContinuousUseStart() && !uiGesture) || (m_Callback.m_IsFullbody && !uiGesture && m_HIC.IsWeaponRaised())) 
            {
                if (m_CurrentGestureID == EmoteConstants.ID_EMOTE_SUICIDE && m_HIC.IsSingleUse())
                {
                    if (m_Callback.GetState() == m_Callback.STATE_LOOP_LOOP)
                    {
                        CommitSuicide();
                    }
                    else
                    {
                        return;
                    }
                }
                else if ((m_CurrentGestureID == EmoteConstants.ID_EMOTE_THUMB || m_CurrentGestureID == EmoteConstants.ID_EMOTE_THUMBDOWN) && m_HIC.IsSingleUse())
                {
                    m_Callback.InternalCommand(DayZPlayerConstants.CMD_ACTIONINT_ACTION);
                }
                else if (m_HIC.IsSingleUse() && (m_CurrentGestureID == EmoteConstants.ID_EMOTE_RPS || m_CurrentGestureID == EmoteConstants.ID_EMOTE_RPS_R || m_CurrentGestureID == EmoteConstants.ID_EMOTE_RPS_P || m_CurrentGestureID == EmoteConstants.ID_EMOTE_RPS_S))
                {
                    if (m_RPSOutcome != -1)
                    {
                        if (m_RPSOutcome == 0)
                        {
                            m_Callback.InternalCommand(DayZPlayerConstants.CMD_ACTIONINT_RPS_ROCK);
                        }
                        else if (m_RPSOutcome == 1)
                        {
                            m_Callback.InternalCommand(DayZPlayerConstants.CMD_ACTIONINT_RPS_PAPER);
                        }
                        else if (m_RPSOutcome == 2)
                        {
                            m_Callback.InternalCommand(DayZPlayerConstants.CMD_ACTIONINT_RPS_SCISSORS);
                        }
                        m_RPSOutcome = -1;
                    }
                    else
                    {
                        m_Callback.InternalCommand(DayZPlayerConstants.CMD_ACTIONINT_END);
                    }
                }
                else if (m_CurrentGestureID != EmoteConstants.ID_EMOTE_SUICIDE || (m_CurrentGestureID == EmoteConstants.ID_EMOTE_SUICIDE && m_Callback.GetState() < 3))
                {
                    SendEmoteRequestSync(CALLBACK_CMD_END);
                }
                else if (m_CurrentGestureID == EmoteConstants.ID_EMOTE_SUICIDE)
                {
                    SendEmoteRequestSync(CALLBACK_CMD_END);
                }
            }
            
            if (m_LastMask != -1 && m_Player.IsPlayerInStance(DayZPlayerConstants.STANCEMASK_PRONE))
            {
                m_Callback.Cancel();
            }
            
            if (m_MenuEmote && !m_MenuEmote.IsStartGuaranteed() && m_bEmoteIsPlaying)
            {
                SendEmoteRequestSync(CALLBACK_CMD_END);
            }
            
            if (m_DeferredEmoteExecution == CALLBACK_CMD_END)
            {
                EndCallbackCommand();
            }
            
            if (m_DeferredEmoteExecution == CALLBACK_CMD_GESTURE_INTERRUPT)
            {
                InterruptCallbackCommand();
            }
        }
        //no m_Callback exists
        else
        {
            if (m_bEmoteIsRequestPending && (m_Player.IsUnconscious() || !m_Player.IsAlive()))
            {
                SetPending(false);
            }
            
            if (m_bEmoteIsPlaying)
            {
                OnEmoteEnd();
            }
            else if (!m_Player.GetItemInHands() && m_IsSurrendered && !m_ItemToBeCreated && (!m_MenuEmote || m_MenuEmote.GetForced() != EmoteLauncher.FORCE_NONE)) //play only when there is time to do so
            {
                PlaySurrenderInOut(false);
                return;
            }
            // getting out of surrender state
            else if (m_IsSurrendered && m_Player.GetItemInHands() && (m_HIC.IsSingleUse() || m_HIC.IsContinuousUseStart() || m_HIC.IsWeaponRaised()))
            {
                if (m_Player.GetItemInHands())
                    m_Player.GetItemInHands().DeleteSafe();//Note, this keeps item 'alive' until it is released by all the systems (inventory swapping etc.)
                return;
            }
            // fallback in case lock does not end properly
            else if (m_IsSurrendered && (!m_Player.GetItemInHands() || (m_Player.GetItemInHands() && m_Player.GetItemInHands().GetType() != "SurrenderDummyItem" && m_EmoteLockState)))
            {
                ClearSurrenderState();
                return;
            }
            //actual emote launch
            else if (m_DeferredEmoteExecution > CALLBACK_CMD_INVALID)
            {
                PlayEmote(m_DeferredEmoteExecution);
                //m_DeferredGuaranteedEmoteId = CALLBACK_CMD_INVALID;
            }
            else if (m_DeferredGuaranteedEmoteId > CALLBACK_CMD_INVALID)
            {
                PlayEmote(m_DeferredGuaranteedEmoteId);
                m_DeferredGuaranteedEmoteId = CALLBACK_CMD_INVALID;
            }
            //client-side emote launcher
            else if (!m_bEmoteIsPlaying && m_MenuEmote && !m_MenuEmote.WasSynced() && !g_Game.IsDedicatedServer())
            {
                SendEmoteRequestSyncEx(m_MenuEmote);
            }
            else if (!m_MenuEmote && gestureSlot > 0)
            {
                CreateEmoteCBFromMenu(gestureSlot,true); //translation no longer needed
            }
        }
    }

Перекрестные ссылки CALLBACK_CMD_END, CALLBACK_CMD_GESTURE_INTERRUPT, CALLBACK_CMD_INSTACANCEL, CALLBACK_CMD_INVALID, ClearDeferredExecution(), ClearEmoteLauncher(), ClearSurrenderState(), CommitSuicide(), CreateEmoteCBFromMenu(), DayZPlayerUtils(), DetermineGestureIndex(), EndCallbackCommand(), EmoteLauncher::FORCE_DIFFERENT, EmoteLauncher::FORCE_NONE, g_Game, EmoteBase::GetStanceMaskFullbody(), EmoteConstants::ID_EMOTE_RPS, EmoteConstants::ID_EMOTE_RPS_P, EmoteConstants::ID_EMOTE_RPS_R, EmoteConstants::ID_EMOTE_RPS_S, EmoteConstants::ID_EMOTE_SITA, EmoteConstants::ID_EMOTE_SUICIDE, EmoteConstants::ID_EMOTE_THUMB, EmoteConstants::ID_EMOTE_THUMBDOWN, InterruptCallbackCommand(), InterruptGestureCheck(), InterruptWaterCheck(), IsEmotePlaying(), m_bEmoteIsPlaying, m_bEmoteIsRequestPending, m_Callback, m_CancelEmote, m_CurrentGestureID, m_DeferredEmoteExecution, m_DeferredEmoteLauncherCleanup, m_DeferredGuaranteedEmoteId, m_DisconnectEmoteQueued, m_EmoteLockState, m_GestureInterruptInput, m_HIC, m_InstantCancelEmote, m_IsSurrendered, m_ItemToBeCreated, m_LastMask, m_MenuEmote, m_NameEmoteMap, m_RPSOutcome, MENU_GESTURES, MENU_INVENTORY, OnEmoteEnd(), PlayEmote(), PlaySurrenderInOut(), SendEmoteRequestSync(), SendEmoteRequestSyncEx(), SetEmoteLockState() и SetPending().