OnStepEvent()

void DayZPlayer::OnStepEvent ( string pEventType, string pUserString, int pUserInt )

inlineprotected

Event Processing

См. определение в файле DayZPlayerImplement.c строка 3269

    {
        vector orientation;
        vector position = GetPosition();
        DayZPlayerType playerType = GetDayZPlayerType();
        HumanMovementState  state = new HumanMovementState();
        GetMovementState(state);
        
        SurfaceInfo surfaceInfo;
        if (pUserInt < 100)
        {
            string boneName = "";
            if (pUserInt % 2 == 1)
            {
                boneName = "leftfoot";
                surfaceInfo = g_Game.GetSurfaceInfoUnderObjectByBone(this, SurfaceAnimationBone.LeftBackLimb);
                if (!surfaceInfo)
                {
                    surfaceInfo = g_Game.GetSurfaceInfoUnderObjectByBone(this, SurfaceAnimationBone.RightBackLimb);
                    boneName = "rightfoot";
                }
            }
            else
            {
                boneName = "rightfoot";
                surfaceInfo = g_Game.GetSurfaceInfoUnderObjectByBone(this, SurfaceAnimationBone.RightBackLimb);
                if (!surfaceInfo)
                {
                    surfaceInfo = g_Game.GetSurfaceInfoUnderObjectByBone(this, SurfaceAnimationBone.LeftBackLimb);
                    boneName = "leftfoot";
                }
            }
            
            if (GetInstanceType() == DayZPlayerInstanceType.INSTANCETYPE_SERVER || !GetGame().IsMultiplayer())
            {
                //synced dusty ceiling effect
                if (surfaceInfo)
                {
                    HandleCeilingDustStepEffect(surfaceInfo, boneName);
                }
            }
            
            #ifdef DIAG_DEVELOPER
            if (GetInstanceType() == DayZPlayerInstanceType.INSTANCETYPE_CLIENT)
            {
                if (DiagMenu.GetBool(DiagMenuIDs.MISC_PLAYER_SURFACE_DEBUG))
                {
                    string surfaceType = "NULL";
                    if (surfaceInfo)
                        surfaceType = surfaceInfo.GetSurfaceType();
                    
                    CharacterStepsDebug.SetStepData(boneName, surfaceType);
                }
            }
            #endif
        }
        
        #ifndef SERVER
        #ifndef NO_GUI
        DayZPlayerTypeStepSoundLookupTable table = playerType.GetStepSoundLookupTable();
        SoundObjectBuilder soundBuilder = NULL;
        if (pUserInt < 100)
        {
            if (surfaceInfo)
            {
                m_LastSurfaceUnderHash = surfaceInfo.GetSurfaceType().Hash();
                
                if (state.m_iMovement == DayZPlayerConstants.MOVEMENTIDX_SPRINT)
                {
                    orientation = -GetDirection();//Using direction to compute forward dot product of surface in the direction oposite player
                
                    vector surfaceNormal = g_Game.SurfaceGetNormal(position[0], position[2]);
                    float dotWithForward = vector.Dot(surfaceNormal, orientation);
                
                    float pitch = Math.Atan2(-dotWithForward, surfaceNormal[1]) * Math.RAD2DEG;
                
                    //VectorToYaw using first and second float insted of first and third then why it is need adjustment
                    orientation[1] = orientation[2]; 
                    orientation[2] = 0;
                
                    float yaw = orientation.VectorToYaw();
                
                    orientation[0] = -yaw + 90; 
                    orientation[1] = pitch;
 
 
                    int stepParticleID = surfaceInfo.GetStepParticleId();
                    if (stepParticleID > 0)
                    {
                        ParticleSource source = ParticleManager.GetInstance().PlayInWorldEx(stepParticleID, null, position);
                        //Direction align with surface in the opposite direction to the player
                        source.SetOrientation(orientation);
                    }
                }
                
                soundBuilder = table.GetSoundBuilder(pUserInt, state.m_iMovement, m_LastSurfaceUnderHash, GetBootsType());
            }
        }
        else
        {
            surfaceInfo = g_Game.GetSurfaceInfoUnderObject(this);
            if (surfaceInfo)
                m_LastSurfaceUnderHash = surfaceInfo.GetSurfaceType().Hash();
            
            soundBuilder = table.GetSoundBuilder(pUserInt, state.m_iMovement, m_LastSurfaceUnderHash, GetBootsType());
        }
 
        if (soundBuilder != null && g_Game.GetPlayer())
        {
            m_StepCounterVegetation++;
 
            if (m_StepCounterVegetation >= 3)
            {
                m_StepCounterVegetation = 0;
                g_Game.ProfilerStart("Player_Vegetation_Sounds");
 
                orientation = vector.Zero;
                vector edgeLength = Vector(0.75, 2.5, 0.75);
                array<Object> excludedObjects = new array<Object>();
                excludedObjects.Insert(this);
                array<Object> collidedObjects = new array<Object>();
                
                if (g_Game.IsBoxCollidingGeometry(position, orientation, edgeLength, ObjIntersectView, ObjIntersectNone, excludedObjects, collidedObjects))
                {
                    foreach (Object obj : collidedObjects)
                    {
                        WoodBase colPlant;
                        if (Class.CastTo(colPlant, obj))
                        {
                            if (colPlant.HasPlayerCollisionParticle() && state.m_iMovement > DayZPlayerConstants.MOVEMENTIDX_WALK)
                                MiscEffects.PlayVegetationCollideParticles(colPlant, this);
                            
                            if (colPlant.HasPlayerCollisionSound())
                            {
                                SoundObject vegSoundObject;
                                 
                                StaticObjectType plantType = StaticObjectType.Cast(colPlant.GetEntityType());
 
                                //custom lookup first
                                SoundObjectBuilder vegSoundObjectBuilder = plantType.GetVegetationSoundBuilderFromEventID(pUserInt);
                                if (vegSoundObjectBuilder)
                                {
                                    vegSoundObject = vegSoundObjectBuilder.BuildSoundObject();
                                }
                                else //then generic
                                {
                                    array<ref VegetationSound> vegSoundArray = playerType.GetVegetationSounds();
                                    foreach (VegetationSound vegetationSound: vegSoundArray)
                                    {
                                        if (vegetationSound.GetAnimEventIds().Find(pUserInt) >= 0)
                                        {
                                            vegSoundObjectBuilder = vegetationSound.GetSoundObjectBuilder();
                                            vegSoundObject = vegSoundObjectBuilder.BuildSoundObject();
                                            break;
                                        }
                                    }
                                }
                                
                                if (vegSoundObject != null)
                                {
                                    AttenuateSoundIfNecessary(vegSoundObject);
                                    PlaySound(vegSoundObject, vegSoundObjectBuilder);
                                }
                                
                                break;
                            }
                        }
                    }
                }
 
                g_Game.ProfilerStop("Player_Vegetation_Sounds");
            }
                
            SoundObject soundObject = soundBuilder.BuildSoundObject();
            if (soundObject != null)
            {
                AttenuateSoundIfNecessary(soundObject);
                PlaySound(soundObject, soundBuilder);
            }
            
        }
        #endif
        #endif
        
        if (g_Game.IsServer())
        {
            m_StepCounter++;//move outside of server condition if needed on client as well
 
            float noiseMultiplier = 0;          
            
            NoiseParams noiseParams;
            if (state.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_ERECT || state.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDERECT)
                noiseParams = playerType.GetNoiseParamsStand();
            else if (state.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_CROUCH || state.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDCROUCH)
                noiseParams = playerType.GetNoiseParamsCrouch();
            else if (state.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_PRONE || state.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDPRONE)
                noiseParams = playerType.GetNoiseParamsProne();
            else
            {
                Debug.Log(string.Format("Wrong stance, id: %1 using backup with stand stance (id: 0)", state.m_iStanceIdx));
                noiseParams = playerType.GetNoiseParamsStand();
            }
            
            noiseMultiplier = NoiseAIEvaluate.GetNoiseMultiplier(this);
                                    
            AddNoise(noiseParams, noiseMultiplier);
            
            if ((m_StepCounter % PlayerConstants.CHECK_EVERY_N_STEP) == 0)
            {
                ProcessFeetDamageServer(pUserInt);
                m_StepCounter = 0;
            }
        }
    }

Перекрестные ссылки AddNoise(), Math::Atan2(), AttenuateSoundIfNecessary(), Class::CastTo(), PlayerConstants::CHECK_EVERY_N_STEP, DayZPlayerType(), vector::Dot(), g_Game, DiagMenu::GetBool(), GetBootsType(), GetDayZPlayerType(), GetGame(), GetInstanceType(), NoiseAIEvaluate::GetNoiseMultiplier(), GetPosition(), DayZPlayerTypeStepSoundLookupTable::GetSoundBuilder(), SurfaceInfo::GetStepParticleId(), SurfaceInfo::GetSurfaceType(), StaticObjectType::GetVegetationSoundBuilderFromEventID(), HandleCeilingDustStepEffect(), string::Hash(), Debug::Log(), HumanMovementState::m_iMovement, HumanMovementState::m_iStanceIdx, m_LastSurfaceUnderHash, m_StepCounter, NoiseParams(), orientation, ParticleManager(), PlaySound(), MiscEffects::PlayVegetationCollideParticles(), position, ProcessFeetDamageServer(), Math::RAD2DEG, SoundObjectBuilder(), Vector(), WoodBase() и vector::Zero.