CreateOrgan()

ItemBase CreateOrgan	(	PlayerBase	player,
		vector	body_pos,
		string	item_to_spawn,
		string	cfg_skinning_organ_class,
		ItemBase	tool )

См. определение в файле ActionSkinning.c строка 91

    {
        // Create item from config
        ItemBase added_item;
        vector posHead;
        MiscGameplayFunctions.GetHeadBonePos(player,posHead);
        vector posRandom = MiscGameplayFunctions.GetRandomizedPositionVerified(posHead,body_pos,UAItemsSpreadRadius.NARROW,player);
        Class.CastTo(added_item,  GetGame().CreateObjectEx(item_to_spawn, posRandom, ECE_PLACE_ON_SURFACE));
        
        // Check if skinning is configured for this body
        if (!added_item)
            return null;
        
        // Set item's quantity from config, if it's defined there.
        float item_quantity = 0;
        array<float> quant_min_max = new array<float>;
        array<float> quant_min_max_coef = new array<float>;
        
        GetGame().ConfigGetFloatArray(cfg_skinning_organ_class + "quantityMinMax", quant_min_max);
        GetGame().ConfigGetFloatArray(cfg_skinning_organ_class + "quantityMinMaxCoef", quant_min_max_coef);
        
        // Read config for quantity value
        if (quant_min_max.Count() > 0)
        {
            float soft_skill_manipulated_value = (quant_min_max.Get(0)+ quant_min_max.Get(1)) / 2;
            item_quantity = Math.RandomFloat(soft_skill_manipulated_value, quant_min_max.Get(1));
        }
        
        if (quant_min_max_coef.Count() > 0)
        {
            float coef = Math.RandomFloat(quant_min_max_coef.Get(0), quant_min_max_coef.Get(1));
            item_quantity = added_item.GetQuantityMax() * coef;
        }
        
        if (GetGame().ConfigGetFloat(cfg_skinning_organ_class + "quantity") > 0)
            item_quantity = g_Game.ConfigGetFloat(cfg_skinning_organ_class + "quantity");
        
        if (GetGame().ConfigGetFloat(cfg_skinning_organ_class + "quantityCoef") > 0)
        {
            float coef2 = g_Game.ConfigGetFloat(cfg_skinning_organ_class + "quantityCoef");
            item_quantity = added_item.GetQuantityMax() * coef2;
        }
        
        if (item_quantity > 0)
        {
            item_quantity = Math.Round(item_quantity);
            added_item.SetQuantity(item_quantity, false);
        }
        
        // Transfer tool's damage to the item's condition
        float item_apply_tool_damage_coef = GetGame().ConfigGetFloat(cfg_skinning_organ_class + "transferToolDamageCoef");
        
        if (item_apply_tool_damage_coef > 0)
        {
            float tool_dmg_coef = 1 - tool.GetHealth01();
            float organ_dmg_coef = tool_dmg_coef * item_apply_tool_damage_coef;
            added_item.DecreaseHealthCoef(organ_dmg_coef);
        }
        
        added_item.InsertAgent(eAgents.SALMONELLA, 1);
        return added_item;
    }

Перекрестные ссылки Class::CastTo(), ECE_PLACE_ON_SURFACE, g_Game, GetGame(), UAItemsSpreadRadius::NARROW, Math::RandomFloat(), Math::Round() и ItemBase::SetQuantity().

Используется в SpawnItems().