HandleWeapons()

void DayZPlayer::HandleWeapons ( float pDt, Entity pInHands, HumanInputController pInputs, out bool pExitIronSights )

inlineprotected

HandleWeapons

fire

См. определение в файле DayZPlayerImplement.c строка 1009

    {
        HumanCommandWeapons      hcw = GetCommandModifier_Weapons();
        GetDayZPlayerInventory().HandleWeaponEvents(pDt, pExitIronSights);
 
        Weapon_Base weapon;
        Class.CastTo(weapon, pInHands);
        ItemOptics optic = weapon.GetAttachedOptics();
        
        CheckLiftWeapon();
        ProcessLiftWeapon();
        
        GetMovementState(m_MovementState);
        
        // obstruction
        bool    wantedLift          = m_LiftWeapon_player;
        bool    currentLift         = hcw.IsWeaponLifted();
        if (wantedLift != currentLift) 
        {
            hcw.LiftWeapon(wantedLift);
            // Reset the velocity, cause at this point we might need to start moving in the opposite direction rather rapidly,
            // to prevent the obstruction from smashing the player's head while lifting
            m_fObstructionSmoothVelocity[0] = 0;
        }       
        
        float   wantedObstruction   = m_ObstructWeapon_player;
        float   currentObstruction  = hcw.GetWeaponObstruction();
        if (wantedObstruction != currentObstruction)
        {
            // The following times are times chosen by observation; the following values produced
            // consistent and relatively nicely looking results and were OK'd by the animators.
            const float outTime    = 0.150;   // duration when smoothing hi -> lo
            const float inTime     = 0.010;   // duration when smoothing lo -> hi
            const float inTimeLift = 0.100;   // duration when smoothing in during lift
            
            float smoothTime;
            if (wantedLift) // When lifting always transition rather quickly
            {
                wantedObstruction = 0.0;
                smoothTime = inTimeLift;
            }
            else // Otherwise we can take our time based on the delta
            {
                float t = Math.Clamp(Math.AbsFloat(wantedObstruction-currentObstruction), 0, 1);
                smoothTime = Math.Lerp(outTime, inTime, t);
            }
            
            // Do the interpolation and clamp to wanted value if the change is below certain threshold, to prevent uneccessary interpolation
            m_fObstructionSmooth = Math.SmoothCD(m_fObstructionSmooth, wantedObstruction, m_fObstructionSmoothVelocity, smoothTime, 6.0, pDt);
            if (Math.AbsFloat(m_fObstructionSmooth-wantedObstruction) < 0.0001) 
            { 
                m_fObstructionSmooth = wantedObstruction;
            }
            
            #ifdef DIAG_DEVELOPER
            if (DiagMenu.GetValue(DiagMenuIDs.WEAPON_DISABLE_OBSTRUCTION_INTERPOLATION))
                m_fObstructionSmooth = wantedObstruction;
            #endif
                
            hcw.ObstructWeapon(m_fObstructionSmooth);
            
            #ifndef SERVER
            #ifdef DIAG_DEVELOPER
            PluginDiagMenuClient.GetWeaponLiftDiag().Data().SetInterpolation( inTime, inTimeLift, outTime, smoothTime, m_fObstructionSmooth, currentObstruction, wantedObstruction );
            #endif
            #endif
        }
        // !obstruction
        
        // hold breath
        if (pInputs.IsHoldBreath() && m_MovementState.IsRaised() && (IsInIronsights() || IsInOptics()))
        {
            m_IsTryingHoldBreath = true;
        }
        else
        {
            m_IsTryingHoldBreath = false;
        }
        
        if (pInputs.IsFireModeChange())
        {
            GetWeaponManager().SetNextMuzzleMode();
        }
        if (pInputs.IsZeroingUp())
        {
            if (optic && (optic.IsInOptics() || optic.IsUsingWeaponIronsightsOverride()))
            {
                optic.StepZeroingUp();
            }
            else
            {
                weapon.StepZeroingUpAllMuzzles();
            }
        }
        if (pInputs.IsZeroingDown())
        {
            if (optic && (optic.IsInOptics() || optic.IsUsingWeaponIronsightsOverride()))
            {
                optic.StepZeroingDown();
            }
            else
            {
                weapon.StepZeroingDownAllMuzzles();
            }
        }
        
        if (!m_LiftWeapon_player && (m_CameraIronsight || !weapon.CanEnterIronsights() || m_CameraOptics/*m_ForceHandleOptics*/))     // HACK straight to optics, if ironsights not allowed
        {
            if (optic)
                HandleOptic(optic, false, pInputs, pExitIronSights);
        }
        
        if (!m_MovementState.IsRaised())
        {
            m_IsFireWeaponRaised = false; //legacy reasons
            if (weapon && weapon.IsInOptics())
            {
                weapon.ExitOptics();
            }
            
            ResetWeaponRaiseProgress();
 
            return; // if not raised => return
        }
        else
        {
            m_IsFireWeaponRaised = true; //legacy reasons
            if (!IsWeaponRaiseCompleted())
            {
                m_WeaponRaiseTime += pDt;
            }
            
            if (m_WeaponRaiseTime >= PlayerConstants.WEAPON_RAISE_BLEND_DELAY)
            {
                CompleteWeaponRaise();
            }
        }
        
        if (GetWeaponManager().CanFire(weapon))
        {
            bool autofire = weapon.GetCurrentModeAutoFire(weapon.GetCurrentMuzzle()) && weapon.IsChamberEjectable(weapon.GetCurrentMuzzle());
            int burst = weapon.GetCurrentModeBurstSize(weapon.GetCurrentMuzzle());
            int burst_count = weapon.GetBurstCount();
            if (!autofire && (burst < 2 || burst_count < 1))
            {
                if (pInputs.IsAttackButtonDown() && GetInputInterface().SyncedValue("UAWeaponMeleeAttack") == 0 && GetInputInterface().SyncedValue("UAHeavyMeleeAttack") == 0)
                {
                    GetWeaponManager().Fire(weapon);
                }
            }
            else if (autofire || burst > 1)
            {
#ifdef DIAG_DEVELOPER
                int burst_option = GetWeaponManager().GetBurstOption();
                if (burst_option == 0)
                {
#endif
                    if (pInputs.IsAttackButton() && GetInputInterface().SyncedValue("UAWeaponMeleeAttack") == 0 && GetInputInterface().SyncedValue("UAHeavyMeleeAttack") == 0)
                    {
                        if (autofire || burst_count < burst)
                        {
                            GetWeaponManager().Fire(weapon);
                        }
                    }
                    else
                    {
                        weapon.ResetBurstCount();   
                    }
#ifdef DIAG_DEVELOPER
                }
                else if (burst_option == 1)
                {
                    if (burst > 1 && burst_count == burst)
                    {
                        weapon.ResetBurstCount();   
                    }
                    else if (burst > 1 && burst_count < burst)
                    {
                        GetWeaponManager().Fire(weapon);    
                    }
                    else
                    {
                        //Autofire
                        if (pInputs.IsAttackButton())
                        {
                            GetWeaponManager().Fire(weapon);    
                        }                       
                    }   
                }
#endif
            }
        }
 
        #ifdef PLATFORM_CONSOLE
        if (g_Game.GetInput().LocalRelease("UAFire", false) || m_ShouldReload)
        {
            if (!weapon.IsWaitingForActionFinish() && !IsFighting())
            {
                int muzzle_index = weapon.GetCurrentMuzzle();
            
                if (weapon.IsChamberFiredOut(muzzle_index))
                {
                    if (weapon.CanProcessWeaponEvents())
                    {
                        if (GetWeaponManager().CanEjectBullet(weapon))
                        {
                            GetWeaponManager().EjectBullet();
                            pExitIronSights = true;
                            m_ShouldReload = false;
                        }
                    }
                }
            }
            else
            {
                m_ShouldReload = true;
            }
        }
        #endif
    }

Перекрестные ссылки Math::AbsFloat(), Class::CastTo(), CheckLiftWeapon(), Math::Clamp(), CompleteWeaponRaise(), g_Game, GetDayZPlayerInventory(), DiagMenu::GetValue(), GetWeaponManager(), HumanCommandWeapons::GetWeaponObstruction(), HandleOptic(), HumanInputController::IsAttackButton(), HumanInputController::IsAttackButtonDown(), IsFighting(), HumanInputController::IsFireModeChange(), HumanInputController::IsHoldBreath(), IsInIronsights(), IsInOptics(), ItemOptics::IsInOptics(), ItemOptics::IsUsingWeaponIronsightsOverride(), HumanCommandWeapons::IsWeaponLifted(), IsWeaponRaiseCompleted(), HumanInputController::IsZeroingDown(), HumanInputController::IsZeroingUp(), Math::Lerp(), HumanCommandWeapons::LiftWeapon(), m_CameraIronsight, m_CameraOptics, m_fObstructionSmooth, m_fObstructionSmoothVelocity, m_IsFireWeaponRaised, m_IsTryingHoldBreath, m_LiftWeapon_player, m_MovementState, m_ObstructWeapon_player, m_ShouldReload, m_WeaponRaiseTime, HumanCommandWeapons::ObstructWeapon(), ProcessLiftWeapon(), ResetWeaponRaiseProgress(), Math::SmoothCD(), ItemOptics::StepZeroingDown(), ItemOptics::StepZeroingUp() и PlayerConstants::WEAPON_RAISE_BLEND_DELAY.

Используется в CommandHandler().