HandleOptic()

void DayZPlayer::HandleOptic ( notnull ItemOptics optic, bool inHands, HumanInputController pInputs, out bool pExitOptics )

inlineprotected

См. определение в файле DayZPlayerImplement.c строка 1245

    {
        UAInterface input = GetInputInterface();
        if (!input)
        {
            return;
        }
 
        Weapon_Base weapon;
        int FOVcount;
        bool controllerPressIn;
        bool controllerPressOut;
        
        if (input.SyncedPress_ID(UAZoomInOptics))
        {
            weapon = Weapon_Base.Cast(optic.GetHierarchyParent());
            FOVcount = optic.GetStepFOVCount();
            controllerPressIn = input.SyncedPress_ID(UAZoomInOpticsControllerHelper);
        
            if (weapon && m_CameraIronsight && !m_CameraOptics)
            {
                SetIronsights(false);
                SwitchOptics(optic,true);
                optic.SetStepFOVIndex(0);
            }
            else if (m_CameraOptics)
            {
                if (controllerPressIn) //controller
                {
                    if (!optic.StepFOVUp())
                    {
                        if (FOVcount > 0)
                        {
                            optic.SetStepFOVIndex(0); //loop to minimum magnification
                        }
                        
                        if (weapon && weapon.CanEnterIronsights()) //loop into ironsights
                        {
                            SwitchOptics(optic,false);
                            SetIronsights(true);
                        }
                    }
                }
                else //m&k
                {
                    optic.StepFOVUp();
                }
            }
        }
        
        if (input.SyncedPress_ID(UAZoomOutOptics))
        {
            weapon = Weapon_Base.Cast(optic.GetHierarchyParent());
            FOVcount = optic.GetStepFOVCount();
            controllerPressOut = input.SyncedPress_ID(UAZoomOutOpticsControllerHelper);
            if (m_CameraOptics)
            {
                if (!optic.StepFOVDown())
                {
                    if (controllerPressOut)
                    {
                        if (FOVcount > 0 && (!weapon || !weapon.CanEnterIronsights()))
                        {
                            optic.SetStepFOVIndex(FOVcount - 1); //loop to maximum magnification
                        }
                    }
                    
                    if (weapon && weapon.CanEnterIronsights())
                    {
                        SwitchOptics(optic,false);
                        SetIronsights(true);
                    }
                }
            }
            else if (controllerPressOut && weapon && m_CameraIronsight)
            {
                SwitchOptics(optic,true);
                if (FOVcount > 0)
                {
                    optic.SetStepFOVIndex(FOVcount - 1); //loop to maximum magnification
                }
            }
        }
    }

Перекрестные ссылки m_CameraIronsight, m_CameraOptics, SetIronsights(), SwitchOptics() и UAInterface::SyncedPress_ID().

Используется в CommandHandler() и HandleWeapons().