Heating()

void Heating ( )

protected

См. определение в файле FireplaceBase.c строка 1825

    {
        float temperature;
        float temperatureModifier = 0;
        
        if (IsOpen() && !IsOven())
            CheckForRoofLimited(1000 * TIMER_HEATING_UPDATE_INTERVAL * 5);
        
        //check burning conditions
        if (GetWet() > PARAM_BURN_WET_THRESHOLD)
        {
            StopFire(FireplaceFireState.EXTINGUISHED_FIRE);
            return; 
        }
        else
        {
            if (m_FireConsumables.Count() == 0)
            {
                StopFire();
                return;
            }
        }
        
        //spend actual fire consumable
        float amount = PARAM_FIRE_CONSUM_RATE_AMOUNT * GetFuelBurnRateMP() * TIMER_HEATING_UPDATE_INTERVAL;
        SpendFireConsumable(amount);
        
        //set wetness and alter temperature modifier (which will lower temperature increase because of soaking)
        float rain = g_Game.GetWeather().GetRain().GetActual();
        float combinedWindAndSnowfall = MiscGameplayFunctions.GetCombinedSnowfallWindValue();
 
        if ((rain >= RAIN_EFFECT_LIMIT || combinedWindAndSnowfall >= SNOWFALL_EFFECT_LIMIT) && !IsRoofAbove() && IsOpen() && !IsOven())
        {
            if (rain > combinedWindAndSnowfall)
            {
                AddWetnessToFireplace(RAIN_WETNESS_INCREASE * rain);
                temperatureModifier = PARAM_TEMPERATURE_DECREASE * rain;
            }
            else
            {
                AddWetnessToFireplace(SNOWFALL_WETNESS_INCREASE * combinedWindAndSnowfall);
                temperatureModifier = PARAM_TEMPERATURE_DECREASE * combinedWindAndSnowfall;
            }
        }
        //subtract wetness when heating and not raining above
        else
        {
            AddWetnessToFireplace(-PARAM_WET_HEATING_DECREASE_COEF);
        }
        
        if (m_SurfaceUnderWetnessModifier > 0.0)
            AddWetnessToFireplace(m_SurfaceUnderWetnessModifier * WET_SURFACE_INCREMENT);
 
        // FLAT temperature increase
        temperature = GetTemperature() + (PARAM_TEMPERATURE_INCREASE * TIMER_HEATING_UPDATE_INTERVAL) - temperatureModifier;
        temperature = Math.Clamp(temperature, g_Game.GetMission().GetWorldData().GetBaseEnvTemperatureAtObject(this), m_UTSLFireplace.m_NormalFireplaceTemperatureMax);
        SetTemperatureDirect(temperature); //direct heating (non-systematic approach), freezing, overheating, and other stuff inside 'SetTemperatureEx' are therefore UNHANDLED here!
        m_UTSLFireplace.SetFuelCount(GetFuelCount()); //legacy reasons
        m_UTSLFireplace.SetCurrentTemperature(temperature); //legacy reasons
        m_UTSource.Update(m_UTSSettings, m_UTSLFireplace);
        
        //get newly changed temperature
        temperature = GetTemperature();
        
        //check fire state
        if (GetFireState() != FireplaceFireState.EXTINGUISHING_FIRE)
        {
            RefreshFireState();
        }
        
        //damage cargo items
        BurnItemsInFireplace();
        
        //manage cooking equipment (this applies only for case of cooking pot on a tripod)
        if (HasCookingStand() && m_CookingEquipment)
        {
            CookWithEquipment();
        }
 
        float cookingItemTemperature;
        int i;
        // manage cooking on direct cooking slots
        if (DirectCookingSlotsInUse())
        {
            for (i = 0; i < DIRECT_COOKING_SLOT_COUNT; i++)
            {
                if (m_DirectCookingSlots[i])
                {
                    cookingItemTemperature = m_DirectCookingSlots[i].GetTemperature();
                    CookOnDirectSlot(m_DirectCookingSlots[i], cookingItemTemperature, temperature);
                }
            }
        }
 
        // manage smoking slots
        if (SmokingSlotsInUse())
        {
            for (i = 0; i < SMOKING_SLOT_COUNT; i++)
            {
                if (m_SmokingSlots[i])
                {
                    SmokeOnSmokingSlot(m_SmokingSlots[i], cookingItemTemperature, temperature);
                }
            }
        }
        
        //Make noise for AI, only at night
        if (g_Game.GetWorld().IsNight() && m_CanNoise)
        {
            NoiseSystem noise = g_Game.GetNoiseSystem();
            if (noise && m_NoisePar)
            {
                noise.AddNoisePos(this, GetPosition(), m_NoisePar);
            }
            m_CanNoise = false;
        }
        else
            m_CanNoise = true;
        
        Synchronize();
    }

Перекрестные ссылки NoiseSystem::AddNoisePos(), AddWetnessToFireplace(), BurnItemsInFireplace(), CheckForRoofLimited(), Math::Clamp(), CookOnDirectSlot(), CookWithEquipment(), DIRECT_COOKING_SLOT_COUNT, DirectCookingSlotsInUse(), g_Game, GetFireState(), GetFuelBurnRateMP(), GetFuelCount(), GetPosition(), GetWet(), HasCookingStand(), FireplaceBase::IsOpen(), IsOven(), m_CanNoise, m_CookingEquipment, m_DirectCookingSlots, m_FireConsumables, m_NoisePar, m_SmokingSlots, m_UTSLFireplace, m_UTSource, m_UTSSettings, PARAM_BURN_WET_THRESHOLD, PARAM_FIRE_CONSUM_RATE_AMOUNT, PARAM_TEMPERATURE_DECREASE, PARAM_TEMPERATURE_INCREASE, PARAM_WET_HEATING_DECREASE_COEF, RAIN_EFFECT_LIMIT, RAIN_WETNESS_INCREASE, RefreshFireState(), SmokeOnSmokingSlot(), SMOKING_SLOT_COUNT, SmokingSlotsInUse(), SNOWFALL_EFFECT_LIMIT, SNOWFALL_WETNESS_INCREASE, SpendFireConsumable(), StopFire(), Synchronize(), TIMER_HEATING_UPDATE_INTERVAL и WET_SURFACE_INCREMENT.