EOnPostFrame()

override void Car::EOnPostFrame ( IEntity other, int extra )

inlineprotected

WheelContact

См. определение в файле CarScript.c строка 675

    {
        float carSpeed = GetVelocity(this).Length();
        ParticleParamsOverrideData particleParamsData;
 
        //FX only on Client and in Single
        if ( !g_Game.IsHeadlessOrDedicatedServer() )
        {
            if (EngineIsOn())
            {
                if (!m_VFXComponent.IsEffectPlayed(EVehicleVFXEffect.EXHAUST_SMOKE))
                {
                    particleParamsData = m_VFXComponent.GetParticleParamsOverrideData(EVehicleVFXEffect.EXHAUST_SMOKE);
                    particleParamsData.m_FloatModifiers.InsertAt(carSpeed, 0);
                    m_VFXComponent.PlayEffect(EVehicleVFXEffect.EXHAUST_SMOKE);
                    m_VFXComponent.SetEffectParticleState(EVehicleVFXEffect.EXHAUST_SMOKE, ParticleList.HATCHBACK_EXHAUST_SMOKE);
                }
            
                if (IsVitalRadiator() && GetFluidFraction(CarFluid.COOLANT) < 0.5)
                {
                    if (!m_VFXComponent.IsEffectPlayed(EVehicleVFXEffect.COOLANT_STEAM))
                        m_VFXComponent.PlayEffect(EVehicleVFXEffect.COOLANT_STEAM);
                    else
                    {
                        if (GetFluidFraction(CarFluid.COOLANT) > 0)
                            m_VFXComponent.SetEffectParticleState(EVehicleVFXEffect.COOLANT_STEAM, ParticleList.HATCHBACK_COOLANT_OVERHEATING);
                        else
                            m_VFXComponent.SetEffectParticleState(EVehicleVFXEffect.COOLANT_STEAM, ParticleList.HATCHBACK_COOLANT_OVERHEATED);
                    }
                }
                else
                    m_VFXComponent.StopEffect(EVehicleVFXEffect.COOLANT_STEAM);
            }
            else
            {
                m_VFXComponent.StopEffect(EVehicleVFXEffect.EXHAUST_SMOKE);
                m_VFXComponent.StopEffect(EVehicleVFXEffect.COOLANT_STEAM);
            }
 
            string surface;
        
            if (carSpeed > EffVehicleDust.WHEEL_DUST_THRESHOLD)
            {
                particleParamsData = m_VFXComponent.GetParticleParamsOverrideData(EVehicleVFXEffect.DUST_BEHIND);
                particleParamsData.m_FloatModifiers.InsertAt(carSpeed, 0);
                particleParamsData.m_FloatModifiers.InsertAt(GetWeightCoef(), 1);
                m_VFXComponent.PlayEffect(EVehicleVFXEffect.DUST_BEHIND);
            }
            else
                m_VFXComponent.StopEffect(EVehicleVFXEffect.DUST_BEHIND);
            
            
            int wheelCount = WheelCount();
            TVectorArray wheelsPosition = new TVectorArray();
 
            int i;
            for (i = 0; i < wheelCount; ++i)
                wheelsPosition.InsertAt(Vector(-1, -1, -1), i);
 
            for (i = 0; i < wheelCount; ++i)
            {
                CarWheel wheel = CarWheel.Cast(WheelGetEntity(i));
                if (!wheel)
                    break;
 
                vector wheelPos;
                if (m_VFXComponent.CanPlayEffectGroup(EVehicleVFXEffectGroup.WHEEL_SMOKE))
                {
                    if (WheelHasContact(i))
                    {
                        float wheelSpeed = WheelGetAngularVelocity(i) * wheel.GetRadius();
                        wheelPos = WheelGetContactPosition(i);
                        wheelPos = WorldToModel(wheelPos);
                        wheelsPosition.Set(i, wheelPos);
                        
                        vector wheelVel = dBodyGetVelocityAt(this, wheelPos);
    
                        vector transform[3];
                        transform[2] = WheelGetDirection(i);
                        transform[1] = vector.Up;
                        transform[0] = transform[2] * transform[1];
    
                        wheelVel = wheelVel.InvMultiply3(transform);
    
                        float bodySpeed = wheelVel[2];
 
                        bool applyWheelSmokeEffect = false;
 
                        if ((wheelSpeed > 0 && bodySpeed > 0) || (wheelSpeed < 0 && bodySpeed < 0))
                            applyWheelSmokeEffect = Math.AbsFloat(wheelSpeed) > Math.AbsFloat(bodySpeed) + EffWheelSmoke.WHEEL_SMOKE_THRESHOLD;
                        else
                            applyWheelSmokeEffect = Math.AbsFloat(wheelSpeed) > EffWheelSmoke.WHEEL_SMOKE_THRESHOLD;
                        
                        if (applyWheelSmokeEffect)
                        {                           
                            m_VFXComponent.SetEffectGroupPositions(EVehicleVFXEffectGroup.WHEEL_SMOKE, wheelsPosition);
                            m_VFXComponent.PlayEffectGroup(EVehicleVFXEffectGroup.WHEEL_SMOKE);
                        }
                        else
                            m_VFXComponent.StopEffectGroup(EVehicleVFXEffectGroup.WHEEL_SMOKE);
                    }
                }
                
                // actual wheel position
                wheelPos = WheelGetPositionLS(i);
                wheelsPosition.Set(i, wheelPos);
                
            
                {
                    if (m_VFXComponent.CanPlayEffectGroup(EVehicleVFXEffectGroup.WHEEL_CONTACT))
                    {
                        bool applyWheelContactEffect = Math.AbsFloat(wheelSpeed) > EffWheelContact.SPEED_THRESHOLD;
                        
                        if (wheel && applyWheelContactEffect)
                        {
                            particleParamsData = m_VFXComponent.GetEffectGroupParticleParamsOverrideData(EVehicleVFXEffectGroup.WHEEL_CONTACT);
                            particleParamsData.m_FloatModifiers.InsertAt(carSpeed, 0);
                            particleParamsData.m_FloatModifiers.InsertAt(GetWeightCoef(), 1);
                            m_VFXComponent.SetSurfaceInfo(WheelGetSurface(i));
                            m_VFXComponent.SetEffectGroupPositions(EVehicleVFXEffectGroup.WHEEL_CONTACT, wheelsPosition);
                                    
                            m_VFXComponent.PlayEffectGroup(EVehicleVFXEffectGroup.WHEEL_CONTACT);
                        }
                        else
                            m_VFXComponent.StopEffectGroup(EVehicleVFXEffectGroup.WHEEL_CONTACT);
                    }
                }
            }
        }
    }

Перекрестные ссылки Math::AbsFloat(), dBodyGetVelocityAt(), EngineIsOn(), g_Game, GetFluidFraction(), GetVelocity(), GetWeightCoef(), ParticleList::HATCHBACK_COOLANT_OVERHEATED, ParticleList::HATCHBACK_COOLANT_OVERHEATING, ParticleList::HATCHBACK_EXHAUST_SMOKE, vector::InvMultiply3(), CarScript::IsVitalRadiator(), vector::Length(), m_VFXComponent, EffWheelContact::SPEED_THRESHOLD, vector::Up, Vector(), EffVehicleDust::WHEEL_DUST_THRESHOLD, EffWheelSmoke::WHEEL_SMOKE_THRESHOLD, WheelCount(), WheelGetAngularVelocity(), WheelGetContactPosition(), WheelGetDirection(), WheelGetEntity(), WheelGetPositionLS(), WheelGetSurface() и WheelHasContact().