TargetSelection()

void TargetSelection ( )

protected

См. определение в файле DayZPlayerImplementMeleeCombat.c строка 334

    {
        // Prepare common variables
        PlayerBase player = PlayerBase.Cast(m_DZPlayer);
        vector pos = m_DZPlayer.GetPosition();
        vector rayStart = m_DZPlayer.GetBonePositionWS(m_DZPlayer.GetBoneIndexByName("Head"));
 
        vector cameraPos, cameraRot, cameraDir;
        m_DZPlayer.GetCurrentCameraTransform(cameraPos, cameraDir, cameraRot);
        vector dir = MiscGameplayFunctions.GetHeadingVector(player);
        dir[1] = cameraDir[1];
 
        // Calculate max distances
        float dist = GetRange();
        float angle = GetAngle();
        float dist2 = Math.SqrFloat(dist);
        
        // There's generally 2 TargetSelection calls per animation
        // First to obtain target to move towards during animation
        // Second one is to see if that target is still in range before applying damage to it
        // m_WasHit means the hit event occured, so this is the second call
 
        if (m_WasHit && GetFinisherType() == -1)
        {
            // See if the component is still in range
            if (CanObjectBeTargeted(m_TargetObject) && ( vector.DistanceSq(rayStart, m_TargetObject.GetDamageZonePos(m_HitZoneName)) <= dist2 ))
            {
                m_AllTargetObjects.Insert(m_TargetObject);
                // This result should still be cached, so no need to fill it in again
                return;
            }
        }
        
        // Find a new target
        InternalResetTarget();
        
        Object target;
        vector hitPos;
        int hitZone;
        
        // First pass - Prefer what the player is looking at (only aligneable ones, we will try for nonaligneable later)
        if (HitZoneSelectionRaycastHelper(hitPos, hitZone, target))
        {
            if (m_ForceUntargetable)
            {
                SetTarget(target, hitPos, hitZone);
                return;
            }
 
            if (CanObjectBeTargeted(target) && vector.DistanceSq(rayStart, hitPos) <= dist2)
            {
                m_AllTargetObjects.Insert(target);
                
                SetTarget(target, hitPos, hitZone);
                return;
            }
        }
        
        // Second pass - Try to obtain something aligneable closeby the player watching direction       
        MeleeTargetData targetData = m_MeleeTargeting.GetMeleeTargetEx(new MeleeTargetSettings(pos, dist*0.75, angle, TARGETING_MIN_HEIGHT, TARGETING_MAX_HEIGHT, rayStart, dir, TARGETING_RAY_RADIUS_EX, m_DZPlayer, m_TargetableObjects), m_AllTargetObjects, m_BlacklistedDamageZones);
 
        if (targetData)
        {
            SetTarget(targetData.Obj, targetData.HitPos, targetData.HitComponent);
            return;
        }
        
        // Third pass - We found no aligneable target, check if the target that we are directly looking at is nonalignable (big)
        if (CanObjectBeTargeted(target, true) && vector.DistanceSq(rayStart, hitPos) <= dist2)
        {
            m_AllTargetObjects.Insert(target);
 
            SetTarget(target, hitPos, hitZone);
            return;
        }
    }

Перекрестные ссылки CanObjectBeTargeted(), vector::DistanceSq(), GetAngle(), GetFinisherType(), GetRange(), MeleeTargetData::HitComponent, MeleeTargetData::HitPos, HitZoneSelectionRaycastHelper(), InternalResetTarget(), m_AllTargetObjects, m_BlacklistedDamageZones, m_DZPlayer, m_ForceUntargetable, m_HitZoneName, m_MeleeTargeting, m_TargetableObjects, m_TargetObject, m_WasHit, MeleeTargetSettings(), MeleeTargetData::Obj, SetTarget(), Math::SqrFloat(), TARGETING_MAX_HEIGHT, TARGETING_MIN_HEIGHT и TARGETING_RAY_RADIUS_EX.

Используется в Update().