Event_OnAwake()

override void ComponentEnergyManager::Event_OnAwake ( )

inlineprotected

300 ms

См. определение в файле ComponentEnergyManager.c строка 172

    {
        if (!m_ThisEntityAI)
            return;
        
        string cfg_item = "CfgVehicles " + m_ThisEntityAI.GetType();
        string cfg_energy_manager = cfg_item + " EnergyManager ";
        
        // Read all config parameters
        m_EnergyUsage                  = g_Game.ConfigGetFloat(cfg_energy_manager + "energyUsagePerSecond");
        bool switch_on                  = g_Game.ConfigGetFloat(cfg_energy_manager + "switchOnAtSpawn");
        m_AutoSwitchOff                  = g_Game.ConfigGetFloat(cfg_energy_manager + "autoSwitchOff");
        m_HasElectricityIcon            = g_Game.ConfigGetFloat(cfg_energy_manager + "hasIcon");
        m_AutoSwitchOffWhenInCargo        = g_Game.ConfigGetFloat(cfg_energy_manager + "autoSwitchOffWhenInCargo");
        
        m_EnergyAtSpawn                  = g_Game.ConfigGetFloat(cfg_energy_manager + "energyAtSpawn");
        m_Energy = m_EnergyAtSpawn;
        m_EnergyStorageMax                = g_Game.ConfigGetFloat(cfg_energy_manager + "energyStorageMax");
        m_ReduceMaxEnergyByDamageCoef  = g_Game.ConfigGetFloat(cfg_energy_manager + "reduceMaxEnergyByDamageCoef");
        m_SocketsCount                    = g_Game.ConfigGetFloat(cfg_energy_manager + "powerSocketsCount");
        
        m_IsPassiveDevice              = g_Game.ConfigGetFloat(cfg_energy_manager + "isPassiveDevice");
        m_CordLength                    = g_Game.ConfigGetFloat(cfg_energy_manager + "cordLength");
        m_PlugType                        = g_Game.ConfigGetFloat(cfg_energy_manager + "plugType");
        
        m_AttachmentActionType            = g_Game.ConfigGetFloat(cfg_energy_manager + "attachmentAction");
        m_WetnessExposure              = g_Game.ConfigGetFloat(cfg_energy_manager + "wetnessExposure");
        
        float update_interval           = g_Game.ConfigGetFloat(cfg_energy_manager + "updateInterval");
        
        m_ConvertEnergyToQuantity      = g_Game.ConfigGetFloat(cfg_energy_manager + "convertEnergyToQuantity");
        
        
        // Check if energy->quantity converion is configured properly
        float cfg_max_quantity = g_Game.ConfigGetFloat (cfg_item + " varQuantityMax");
        
        if (m_ConvertEnergyToQuantity  &&  cfg_max_quantity <= 0)
        {
            string error = "Error! Item " + m_ThisEntityAI.GetType() + " has invalid configuration of the energy->quantity conversion feature. To fix this, add 'varQuantityMax' parameter with value higher than 0 to the item's config. Then make sure to re-build the PBO containing this item!";
            Error(error);
            m_ConvertEnergyToQuantity = false;
        }
        else
        {
            if (m_ConvertEnergyToQuantity)
            {
                g_Game.GetCallQueue(CALL_CATEGORY_SYSTEM).CallLater(OnEnergyAdded, 300); 
            }
        }
        
        // Set update interval
        if ( update_interval <= 0 )
            update_interval = DEFAULT_UPDATE_INTERVAL;
        
        SetUpdateInterval( update_interval );
        
        // If energyAtSpawn is present, then use its value for energyStorageMax if that cfg param is not present (for convenience's sake)
        string cfg_check_energy_limit = cfg_energy_manager + "energyStorageMax";
        
        if ( !g_Game.ConfigIsExisting (cfg_check_energy_limit)  &&  m_Energy > 0 )
        {
            m_EnergyStorageMax = m_Energy;
        }
        
        // Fill m_CompatiblePlugTypes
        string cfg_check_plug_types = cfg_energy_manager + "compatiblePlugTypes";
        
        if ( g_Game.ConfigIsExisting (cfg_check_plug_types) )
        {
            m_CompatiblePlugTypes = new TIntArray;
            g_Game.ConfigGetIntArray(cfg_check_plug_types, m_CompatiblePlugTypes);   
        }
        
        if (GetSocketsCount() > 0)
            m_PluggedDevices = new array<EntityAI>;
        
        if ( m_CordLength < 0 )
        {
            m_CordLength = 0;
            string error_message_cord = "Warning! " + m_ThisEntityAI.GetType() + ": config parameter 'cordLength' is less than 0! Cord length should not be negative!";
            DPrint(error_message_cord);
        }
        
        if (GetSocketsCount() > 0)
        {
            m_DeviceByPlugSelection = new map<string,EntityAI>;
            // Prepare the m_DeviceByPlugSelection
            string cfg_animation_sources = "cfgVehicles " + m_ThisEntityAI.GetType() + " " + "AnimationSources ";
            int animation_sources_count = g_Game.ConfigGetChildrenCount(cfg_animation_sources);
            
            for (int i_selection = 0; i_selection < animation_sources_count; i_selection++)
            {
                // TO DO: This could be optimized so not all selections on item are considered as plug/socket selections.
                string selection;
                g_Game.ConfigGetChildName(cfg_animation_sources, i_selection, selection);
                m_DeviceByPlugSelection.Set(selection, NULL);
            }
        }
        
        
        
        // Prepare sockets
        if ( m_SocketsCount > MAX_SOCKETS_COUNT )
        {
            m_SocketsCount = MAX_SOCKETS_COUNT;
            string error_message_sockets = "Error! " + m_ThisEntityAI.GetType() + ": config parameter 'powerSocketsCount' is higher than the current limit (" + MAX_SOCKETS_COUNT.ToString() + ")! Raise the limit (constant MAX_SOCKETS_COUNT) or decrease the powerSocketsCount parameter for this device!";
            DPrint(error_message_sockets);
        }
        
        m_Sockets[MAX_SOCKETS_COUNT]; // Handles selections for plugs in the sockets. Feel free to change the limit if needed.
        
        g_Game.ConfigGetText(cfg_energy_manager + "cordTextureFile", m_CordTextureFile); 
        
        if ( switch_on )
        {
            SwitchOn();
        }
        
        for ( int i = 0; i <= GetSocketsCount(); ++i )
        {
            m_ThisEntityAI.HideSelection ( SOCKET_ + i.ToString() + _PLUGGED );
        }
        
        // Show/hide inventory sockets
        m_ShowSocketsInInventory = false;
        if ( GetSocketsCount() > 0  &&  IsPlugCompatible(PLUG_COMMON_APPLIANCE)  &&  m_ThisEntityAI.GetType() != "MetalWire" ) // metal wire filter is hopefully temporal.
        {
            m_ShowSocketsInInventory = true;
        }
        
        m_CanWork = HasEnoughStoredEnergy();
        
        m_ThisEntityAI.HideSelection( SEL_CORD_PLUGGED );
        
        
        #ifdef DIAG_DEVELOPER
        g_Game.m_EnergyManagerArray.Insert( this );
        #endif
    }

Перекрестные ссылки _PLUGGED, CALL_CATEGORY_SYSTEM, DEFAULT_UPDATE_INTERVAL, DPrint(), Error(), g_Game, GetSocketsCount(), HasEnoughStoredEnergy(), IsPlugCompatible(), m_AttachmentActionType, m_AutoSwitchOff, m_AutoSwitchOffWhenInCargo, m_CanWork, m_CompatiblePlugTypes, m_ConvertEnergyToQuantity, m_CordLength, m_CordTextureFile, m_DeviceByPlugSelection, m_Energy, m_EnergyAtSpawn, m_EnergyStorageMax, m_EnergyUsage, m_HasElectricityIcon, m_IsPassiveDevice, m_PluggedDevices, m_PlugType, m_ReduceMaxEnergyByDamageCoef, m_ShowSocketsInInventory, m_Sockets, m_SocketsCount, Component::m_ThisEntityAI, m_WetnessExposure, MAX_SOCKETS_COUNT, OnEnergyAdded(), PLUG_COMMON_APPLIANCE, SEL_CORD_PLUGGED, SetUpdateInterval(), SOCKET_ и SwitchOn().