UpdateCookingState()

int UpdateCookingState ( Edible_Base item_to_cook, CookingMethodType cooking_method, ItemBase cooking_equipment, float cooking_time_coef )

protected

enable cooking SoundEvent

Change food stage to new, IF DIFFERENT

any foodstage without lard

any foodstage without lard

См. определение в файле Cooking.c строка 196

    {
        //food properties
        float food_temperature = item_to_cook.GetTemperature();
        
        //{min_temperature, time_to_cook, max_temperature (optional)}
        //get next stage name - if next stage is not defined, next stage name will be empty "" and no cooking properties (food_min_temp, food_time_to_cook, food_max_temp) will be set
        FoodStageType new_stage_type = item_to_cook.GetNextFoodStageType(cooking_method);
        
        float food_min_temp     = 0;
        float food_time_to_cook = 0;
        
        //Set next stage cooking properties if next stage possible
        if (item_to_cook.CanChangeToNewStage(cooking_method)) // new_stage_type != NONE
        {
            array<float> next_stage_cooking_properties = new array<float>();
            next_stage_cooking_properties = FoodStage.GetAllCookingPropertiesForStage(new_stage_type, null, item_to_cook.GetType());
            
            food_min_temp = next_stage_cooking_properties.Get(eCookingPropertyIndices.MIN_TEMP); //checked after temperature is changed
            food_time_to_cook = next_stage_cooking_properties.Get(eCookingPropertyIndices.COOK_TIME);
        }
        
        //add temperature
        AddTemperatureToItem(item_to_cook, cooking_equipment, food_min_temp);
        
        //decrease qty of burned items (or cookable items that can't be burned)
        if (item_to_cook.IsItemOverheated())
            DecreaseCookedItemQuantity(item_to_cook,COOKING_FOOD_QUANTITY_DECREASE_AMOUNT_NONE);
        
        //add cooking time if the food can be cooked by this method
        if (food_min_temp > 0 && food_temperature >= food_min_temp)
        {
            item_to_cook.MakeSoundsOnClient(true,cooking_method);
            
            float new_cooking_time = item_to_cook.GetCookingTime() + COOKING_FOOD_TIME_INC_VALUE * cooking_time_coef;
            item_to_cook.SetCookingTime(new_cooking_time);
            
            //progress to next stage
            if (item_to_cook.GetCookingTime() >= food_time_to_cook)
            {
                if (item_to_cook.GetFoodStageType() != new_stage_type)
                {
                    item_to_cook.ChangeFoodStage(new_stage_type);
                    
                    if (cooking_equipment && cooking_equipment != item_to_cook)
                    {
                        if (cooking_method == CookingMethodType.BAKING)
                        {
                            ItemBase lard = GetItemTypeFromCargo(COOKING_INGREDIENT_LARD, cooking_equipment);
                            if (lard)
                            {
                                //decrease lard quantity
                                float lardQuantity = lard.GetQuantity() - COOKING_LARD_DECREASE_COEF;
                                lardQuantity = Math.Clamp(lardQuantity, 0, lard.GetQuantityMax());
                                lard.SetQuantity(lardQuantity);
                            }
                            else
                            {
                                DecreaseCookedItemQuantity(item_to_cook, COOKING_FOOD_QUANTITY_DECREASE_AMOUNT_NONE);
                            }
                        }
                    }
                    else
                    {
                        DecreaseCookedItemQuantity(item_to_cook, COOKING_FOOD_QUANTITY_DECREASE_AMOUNT_NONE);
                    }
                }
                
                //reset cooking time
                item_to_cook.ResetCookingTime();
                
                return 1;
            }
        }
        else
        {
            item_to_cook.MakeSoundsOnClient(false);
        }
        
        return 0;
    }

Перекрестные ссылки AddTemperatureToItem(), Edible_Base::CanChangeToNewStage(), Edible_Base::ChangeFoodStage(), Math::Clamp(), COOKING_FOOD_QUANTITY_DECREASE_AMOUNT_NONE, COOKING_FOOD_TIME_INC_VALUE, COOKING_INGREDIENT_LARD, COOKING_LARD_DECREASE_COEF, DecreaseCookedItemQuantity(), Edible_Base::GetCookingTime(), Edible_Base::GetFoodStageType(), GetItemTypeFromCargo(), Edible_Base::GetNextFoodStageType(), Edible_Base::MakeSoundsOnClient(), Edible_Base::ResetCookingTime(), Edible_Base::SetCookingTime() и ItemBase::SetQuantity().

Используется в ProcessItemToCook().