PlayerHitBy()

void PluginBase::PlayerHitBy ( TotalDamageResult damageResult, int damageType, PlayerBase player, EntityAI source, int component, string dmgZone, string ammo )

inlineprotected

См. определение в файле PluginAdminLog.c строка 223

    {
        if ( player && source )     
        {
            string playerPrefix = GetPlayerPrefix( player ,  player.GetIdentity() ) + "[HP: " + player.GetHealth().ToString() + "]";
            string playerPrefix2;
            m_HitMessage = GetHitMessage( damageResult, component, dmgZone, ammo );
            PlayerBase playerSource;
            
            if ( source.IsPlayer() )// Fists
                playerSource = PlayerBase.Cast( source );
            else
                playerSource = PlayerBase.Cast( source.GetHierarchyParent() );
            
            if (playerSource)
                playerPrefix2 = GetPlayerPrefix( playerSource ,  playerSource.GetIdentity() );
            
            switch ( damageType )
            {
                case DamageType.CLOSE_COMBAT: // Player melee, animals, infected 
                
                    if (source.IsZombie() || source.IsAnimal())  // Infected & Animals
                    {
                        if (m_HitFilter == 1)
                            break;
                    
                        m_DisplayName = source.GetDisplayName();
                                                
                        LogPrint( playerPrefix + " hit by " + m_DisplayName + m_HitMessage );  
                    }           
                    else if (source.IsPlayer())// Fists
                    {
                        LogPrint( playerPrefix + " hit by " + playerPrefix2 + m_HitMessage );
                    }
                    else if ( playerSource && (source.IsMeleeWeapon() || source.IsWeapon()))           // Melee weapons
                    {               
                        m_ItemInHands = source.GetDisplayName();
                            
                        LogPrint( playerPrefix + " hit by " + playerPrefix2 + m_HitMessage + " with " + m_ItemInHands );               
                    }
                    else
                    {
                        m_DisplayName = source.GetType();
                    
                        LogPrint( playerPrefix + " hit by " + m_DisplayName + m_HitMessage );                  
                    } 
                    break;
                
                case DamageType.FIRE_ARM: // Player ranged
                
                    if ( source.IsWeapon() && playerSource )
                    {
                        m_ItemInHands = source.GetDisplayName();               
                        m_Distance = vector.Distance( player.GetPosition(), playerSource.GetPosition() );
                    
                        LogPrint( playerPrefix + " hit by " + playerPrefix2 + m_HitMessage + " with " + m_ItemInHands + " from " + m_Distance + " meters ");
                    }
                    else 
                    {
                        m_DisplayName = source.GetType();
                    
                        LogPrint( playerPrefix + " hit by " + m_DisplayName + m_HitMessage );          
                    }
                    break;
                
                case DamageType.EXPLOSION:    // Explosion
                
                    LogPrint( playerPrefix + " hit by explosion (" + ammo + ")" );
                    break;
                        
                case DamageType.STUN:         // unused atm
                
                    LogPrint( playerPrefix + " stunned by " + ammo );
                    break;
                        
                case DamageType.CUSTOM:       // Others (Vehicle hit, fall, fireplace, barbed wire ...)
                    float globalHealthDamage = damageResult.GetDamage("", "Health");
                    if (ammo == DayZPlayerImplementFallDamage.FALL_DAMAGE_AMMO_HEALTH || ammo == DayZPlayerImplementFallDamage.FALL_DAMAGE_AMMO_SHOCK || ammo == DayZPlayerImplementFallDamage.FALL_DAMAGE_AMMO_HEALTH_OTHER_ATTACHMENTS)
                    {
                        if (globalHealthDamage > 0.0)
                            LogPrint(playerPrefix + " hit by " + ammo); 
                    }
                    else if ( source.GetType() == "AreaDamageManager" )  
                    {
                        EntityAI parent = EntityAI.Cast( source );
                        if ( parent )
                        {
                            LogPrint( playerPrefix + " hit by " + parent.GetType() + " with " + ammo ); 
                        }
                    }
                    else if (source.IsTransport())
                    {
                        string vehicle = source.GetType();
                        Transport transport = Transport.Cast(source);
                        Human driver = transport.CrewDriver();
                        playerSource = PlayerBase.Cast(driver);
                        if (playerSource)
                            playerPrefix2 = GetPlayerPrefix( playerSource ,  playerSource.GetIdentity() );
                        else
                            playerPrefix2 = "NO DRIVER";
                    
                        LogPrint( playerPrefix + " hit by " + playerPrefix2 + " with " + ammo + " (" + vehicle + ")" );
                    }
                    else
                    {
                        m_DisplayName = source.GetType();
                                        
                        LogPrint( playerPrefix + " hit by " + m_DisplayName + " with " + ammo );
                    }
                    break;
                                            
                default:
                
                    LogPrint("DEBUG: PlayerHitBy() unknown damageType: " + ammo );
                    break;
            }
        }
        else
        {
            LogPrint("DEBUG: player/source does not exist");
        }
    }

Перекрестные ссылки component, DayZPlayerImplementFallDamage(), vector::Distance(), TotalDamageResult::GetDamage(), GetHitMessage(), GetPlayerPrefix(), EntityAI::IsMeleeWeapon(), LogPrint(), m_DisplayName, m_Distance, m_HitFilter, m_HitMessage и m_ItemInHands.