CreateGroundEffect()

void DustEffectManager::CreateGroundEffect ( )

inlineprotected

См. определение в файле DustEffectsManager.c строка 246

    {
        bool canCreateEffect = true;
        int particleID = ParticleList.NONE;
        vector wind = g_Game.GetWeather().GetWind();
        float windStrength = wind.Normalize();
        vector spawnPoint = GetGroundEffectPotentialPosition();
        
        SurfaceInfo surfaceInfo;
        float spawnPointHeight;
        surfaceInfo = g_Game.GetSurfaceInfoOn(spawnPoint[0], spawnPoint[2], spawnPointHeight);
        spawnPoint[1] = spawnPointHeight;
 
        if (m_GroundEffectTestEndPoint)
        {
            vector endPoint;
            endPoint = spawnPoint + (wind * GROUND_EFFECT_END_TEST_DISTANCE);
            SurfaceInfo endPointSurfaceInfo;
            float endPointSurfaceHeight;
            endPointSurfaceInfo = g_Game.GetSurfaceInfoOn(endPoint[0], endPoint[2], endPointSurfaceHeight);
        
            if (surfaceInfo.GetSurfaceType() != endPointSurfaceInfo.GetSurfaceType())
            {
                canCreateEffect = false;
            }
        }
 
        if (canCreateEffect)
        {
            particleID = surfaceInfo.GetGroundEffectParticleId();
            if (particleID == ParticleList.NONE || particleID == ParticleList.INVALID)
            {
                canCreateEffect = false;
            }
        }
 
        if (canCreateEffect)
        {
            spawnPoint[1] = GetGame().SurfaceY(spawnPoint[0],spawnPoint[2]);
            
            ParticleSource source = ParticleManager.GetInstance().PlayInWorldEx(particleID, null, spawnPoint, "0 0 0", true);
 
            
            float output;
            
            GetParticleParm(source, -1, EmitorParam.LIFETIME,  output);
            GetParticleParm(source, -1, EmitorParam.SIZE,  output);
            
            
            if (m_GroundEffectLifetimeMin >= 0 && m_GroundEffectLifetimeMax >= 0)
                SetParticleParm(source, -1, EmitorParam.LIFETIME, ComputeWindBiasedValue(windStrength, m_GroundEffectLifetimeMin, m_GroundEffectLifetimeMax));
            if (m_GroundEffectSizeMin >= 0 && m_GroundEffectSizeMax >= 0)
                SetParticleParm(source, -1, EmitorParam.SIZE, ComputeWindBiasedValue(windStrength, m_GroundEffectSizeMin, m_GroundEffectSizeMax));
 
            vector dustOrientation = wind;
            
            dustOrientation[0] = wind[0];
            dustOrientation[1] = wind[2];
            
            float yaw = dustOrientation.VectorToYaw();
            
            vector surfaceNormal = GetGame().SurfaceGetNormal(spawnPoint[0],spawnPoint[2]);
            float dotWithForward = vector.Dot(surfaceNormal, wind);
            
            float pitch = Math.Atan2(-dotWithForward, surfaceNormal[1]) * Math.RAD2DEG;
            
            dustOrientation[0] = -yaw;
            dustOrientation[1] = 0;
            dustOrientation[2] = -pitch;
            
            source.SetOrientation(dustOrientation);
        }
    }

Перекрестные ссылки Math::Atan2(), ComputeWindBiasedValue(), vector::Dot(), g_Game, GetGame(), SurfaceInfo::GetGroundEffectParticleId(), GetGroundEffectPotentialPosition(), GetParticleParm(), SurfaceInfo::GetSurfaceType(), GROUND_EFFECT_END_TEST_DISTANCE, ParticleList::INVALID, m_GroundEffectLifetimeMax, m_GroundEffectLifetimeMin, m_GroundEffectSizeMax, m_GroundEffectSizeMin, m_GroundEffectTestEndPoint, ParticleList::NONE, vector::Normalize(), ParticleManager(), Math::RAD2DEG, SetParticleParm() и vector::VectorToYaw().

Используется в UpdateGroundEffect().