RefreshFireplaceVisuals()

void RefreshFireplaceVisuals ( )

protected

single stone; everything else hidden

hide stones stack completely

См. определение в файле FireplaceBase.c строка 665

    {
        if (IsHologram())
        {
            return;
        }
        
        // Light
        #ifndef SERVER
        if (IsBurning()) 
        {
            //turn light on
            if (!GetLightEntity())
            {
                SetLightEntity(FireplaceLight.Cast(ScriptedLightBase.CreateLight(FireplaceLight, GetPosition(), 20)));
                GetLightEntity().AttachOnMemoryPoint(this, "light");
            }
 
            if (GetLightEntity() && GetLightEntity().GetBrightness() > 0)
            {
                // change brightness based on the distance of player to the fireplace
                Object player     = GetGame().GetPlayer();
                float lightDist = m_LightDistance;
 
                if (IsOven())
                {
                    lightDist = 50;
                }
 
                if (player)
                {
                    if (vector.DistanceSq(player.GetPosition(), this.GetPosition()) > lightDist * lightDist)
                    {
                        GetLightEntity().FadeBrightnessTo(0, 5);
                    }
                    else
                    {
                        GetLightEntity().FadeBrightnessTo(FireplaceLight.m_FireplaceBrightness, 5);
                    }
                }
                
                // The following solves an issue with the light point clipping through narrow geometry
                if (IsItemTypeAttached(ATTACHMENT_STONES) || IsBarrelWithHoles() || IsFireplaceIndoor())
                {
                    GetLightEntity().SetInteriorMode();
                }
                else
                {
                    GetLightEntity().SetExteriorMode();
                }
            }
        }
        else
        {
            //turn light off
            if (GetLightEntity())
            {
                GetLightEntity().FadeOut();
            }
        }
        #endif
        
        //set default burn parameters based on fireplace type
        if (IsBarrelWithHoles() || IsFireplaceIndoor() || IsIndoorOven() || IsOven())
        {
            SetFuelBurnRateMP(FUEL_BURN_RATE_OVEN);
        }
        else if (HasStoneCircle())
        {
            SetFuelBurnRateMP(FUEL_BURN_RATE_STONES);
        }
        else
        {
            SetFuelBurnRateMP(FUEL_BURN_RATE_DEFAULT);
        }
        
        // Oven attachments
        if (IsOven())
        {
            //lock attachment slots
            if (!m_OvenAttachmentsLockState)
            {
                LockOvenAttachments(true);
            }
        }
        else
        {
            //unlock attachment slots
            if (m_OvenAttachmentsLockState)
            {
                LockOvenAttachments(false);
            }
        }
        
        //VISUAL STATES
        //Fuel state
        if (GetGame().IsServer())
        {
            // Sticks state
            if (IsItemTypeAttached(ATTACHMENT_STICKS))
                SetAnimationPhase(ANIMATION_STICKS, 0);
            else
                SetAnimationPhase(ANIMATION_STICKS, 1);
            
            // Firewood state
            if (IsItemTypeAttached(ATTACHMENT_FIREWOOD))
            {
                if (IsBurning() && HasAshes())
                {
                    SetAnimationPhase(ANIMATION_BURNT_WOOD, 0); // Because this might not be set under certain circumstances
                    SetAnimationPhase(ANIMATION_WOOD, 1);
                }
                else if (IsWet() || !IsBurning())
                {
                    SetAnimationPhase(ANIMATION_BURNT_WOOD, 1);
                    SetAnimationPhase(ANIMATION_WOOD, 0);
                }
                else
                {
                    SetAnimationPhase(ANIMATION_BURNT_WOOD, 1);
                    SetAnimationPhase(ANIMATION_WOOD, 0);
                }
            }
            else
            {
                SetAnimationPhase(ANIMATION_WOOD, 1);
                SetAnimationPhase(ANIMATION_BURNT_WOOD, 1);
            }   
                
            // Kindling state
            if (GetKindlingCount() != 0)
                SetAnimationPhase(ANIMATION_KINDLING, 0);
            else
                SetAnimationPhase(ANIMATION_KINDLING, 1);
    
            // Ashes state
            if (HasAshes())
                SetAnimationPhase(ANIMATION_ASHES, 0);
            else
                SetAnimationPhase(ANIMATION_ASHES, 1);
 
            // Stone variations
            if (HasStones())
            {
                if (HasStoneCircle())
                {
                    SetAnimationPhase(ANIMATION_STONES, 0);
                    SetAnimationPhase(ANIMATION_STONE, 1);
                }
                else if (IsOven())
                {
                    SetAnimationPhase(ANIMATION_OVEN, 0);
                    SetAnimationPhase(ANIMATION_STONE, 1);
                }
                else
                {
                    SetAnimationPhase(ANIMATION_STONES, 1);
                    SetAnimationPhase(ANIMATION_OVEN, 1);
                    SetAnimationPhase(ANIMATION_STONE, 0);
                }
            }
            else
            {
                SetAnimationPhase(ANIMATION_STONE, 1); 
            }
        }
        
        //refresh physics (with delay)
        GetGame().GetCallQueue(CALL_CATEGORY_GAMEPLAY).Call(RefreshFireplacePhysics);
    }

Перекрестные ссылки ANIMATION_ASHES, ANIMATION_BURNT_WOOD, ANIMATION_KINDLING, ANIMATION_OVEN, ANIMATION_STICKS, ANIMATION_STONE, ANIMATION_STONES, ANIMATION_WOOD, ATTACHMENT_FIREWOOD, ATTACHMENT_STICKS, ATTACHMENT_STONES, ScriptCallQueue::Call(), CALL_CATEGORY_GAMEPLAY, vector::DistanceSq(), FUEL_BURN_RATE_DEFAULT, FUEL_BURN_RATE_OVEN, FUEL_BURN_RATE_STONES, CGame::GetCallQueue(), GetGame(), GetKindlingCount(), GetLightEntity(), CGame::GetPlayer(), GetPosition, HasAshes(), HasStoneCircle(), HasStones(), FireplaceBase::IsBarrelWithHoles(), IsBurning(), IsFireplaceIndoor(), IsHologram(), FireplaceBase::IsIndoorOven(), IsItemTypeAttached(), IsOven(), IsWet(), LockOvenAttachments(), m_LightDistance, m_OvenAttachmentsLockState, RefreshFireplacePhysics(), SetFuelBurnRateMP() и SetLightEntity().

Используется в EEInit(), FireplaceBase::EEItemAttached(), FireplaceIndoor::EEItemAttached(), FireplaceBase::EEItemDetached(), FireplaceIndoor::EEItemDetached(), OnVariablesSynchronized(), SetItemToConsume() и Synchronize().