Update()

void StaminaHandler::Update ( float deltaT, int pCurrentCommandID )

inlineprotected

См. определение в файле StaminaHandler.c строка 489

    {
        #ifdef DIAG_DEVELOPER
        if (m_StaminaDisabled)
            return;
        #endif
        
        if (!m_Player)
            return;
        
        // Process cooldowns - subtract deltaT and remove expired ones
        array<int> expiredCooldowns = new array<int>();
        foreach (int modifier, StaminaCooldownParams cooldownParams : m_CooldownMap)
        {
            cooldownParams.param1 -= deltaT;
            if (cooldownParams.param1 <= 0)
            {
                expiredCooldowns.Insert(modifier);
            }
        }
        
        // Remove expired cooldowns
        foreach (int expiredModifier : expiredCooldowns)
        {
            ResetCooldown(expiredModifier);
        }
        
        // Reset so we get current bonus value once in this update loop and then reuse the cached value within this update call
        m_IsStaminaGainBonusCached = false;
        
        // Check if movement state has changed
        m_MovementStateChanged = HasMovementStateChanged();
        
        bool isAiOrSingleplayer = m_Player.IsAuthorityOwner();
        bool isServerOrSingleplayer = m_Player.IsAuthority();
        
        // Calculates actual max stamina based on player's load
        if (isServerOrSingleplayer)
        {
            float oldCap = m_StaminaCap;
            bool forceLoadRecheck = m_ForceLoadRecheck;
            m_ForceLoadRecheck = false;
            m_PlayerLoad = m_Player.GetWeightEx(forceLoadRecheck);
            
            float loadDiff = Math.AbsFloat(m_PlayerLoad - m_LastPlayerLoad);
            if (forceLoadRecheck || loadDiff > LOAD_DIFF_UPDATE_THRESHOLD)
            {
                RecalculateStaminaCap();
                m_LastPlayerLoad = m_PlayerLoad;
        
                float capDiff = Math.AbsFloat(oldCap - m_StaminaCap);
                if (capDiff > LOAD_DIFF_CAP_UPDATE_THRESHOLD)
                {
                    if (m_Stamina > m_StaminaCap)
                    {
                        m_Stamina = m_StaminaCap;
                    }
        
                    m_StaminaSynced = m_Stamina;
                    m_StaminaCapSynced = m_StaminaCap;
        
                    SyncStaminaEx();
                    m_Time = 0;
                }
            }
        }
        else
        {
            PlayerBaseMove move = PlayerBaseMove.Cast(m_Player.GetNextMove());
            if (move)
            {
                move.m_fStaminaValue = m_Stamina;
                move.m_fStaminaCapacity = m_StaminaCap;
            }
        }
        
        if (isAiOrSingleplayer)
        {
            m_StaminaSynced = m_Stamina;
            m_StaminaCapSynced = m_StaminaCap;
        }
        
        // Process movement if: state changed, we have stamina delta, in cooldown, not initialized, or stamina is bewlow cap
        if (m_MovementStateChanged || m_StaminaDelta != 0 || m_IsInCooldown || !m_InitUpdate || m_Stamina < m_StaminaCap)
            ProcessMovementState();
        
        // Sets current stamina & stores + syncs data with client
        ProcessStaminaChanges(deltaT, isServerOrSingleplayer);
 
        ApplyExhaustion();
        CheckStaminaState();
        
        m_StaminaDelta = 0;
        m_StaminaDepletion = 0; // resets depletion modifier
        m_IsStaminaGainBonusCached = false;
        if (!m_InitUpdate)
            m_InitUpdate = true;
    }

Перекрестные ссылки Math::AbsFloat(), ApplyExhaustion(), CheckStaminaState(), HasMovementStateChanged(), LOAD_DIFF_CAP_UPDATE_THRESHOLD, LOAD_DIFF_UPDATE_THRESHOLD, m_CooldownMap, m_ForceLoadRecheck, m_InitUpdate, m_IsInCooldown, m_IsStaminaGainBonusCached, m_LastPlayerLoad, m_MovementStateChanged, m_Player, m_PlayerLoad, m_Stamina, m_StaminaCap, m_StaminaCapSynced, m_StaminaDelta, m_StaminaDepletion, m_StaminaSynced, m_Time, ProcessMovementState(), ProcessStaminaChanges(), RecalculateStaminaCap(), ResetCooldown() и SyncStaminaEx().