OnEvent() [2/2]

override void MissionBase::OnEvent ( EventType eventTypeId, Param params )

inlineprotected

См. определение в файле missionServer.c строка 309

    {
        PlayerIdentity identity;
        PlayerBase player;
        int counter = 0;
        
        switch (eventTypeId)
        {
        case ClientPrepareEventTypeID:
            ClientPrepareEventParams clientPrepareParams;
            Class.CastTo(clientPrepareParams, params);
            CfgGameplayHandler.SyncDataSendEx(clientPrepareParams.param1);
            CfgPlayerRestrictedAreaHandler.SyncDataSend(clientPrepareParams.param1);
            CfgBunkerBroadcastHandler.SyncDataSend(clientPrepareParams.param1);
            OnClientPrepareEvent(clientPrepareParams.param1, clientPrepareParams.param2, clientPrepareParams.param3, clientPrepareParams.param4, clientPrepareParams.param5);
            break;
 
        case ClientNewEventTypeID:
            ClientNewEventParams newParams;
            Class.CastTo(newParams, params);
            player = OnClientNewEvent(newParams.param1, newParams.param2, newParams.param3);
            if (!player)
            {
                Debug.Log("ClientNewEvent: Player is empty");
                return;
            }
            identity = newParams.param1;
            InvokeOnConnect(player,identity);
            SyncEvents.SendPlayerList();
            
            ControlPersonalLight(player);
            SyncGlobalLighting(player);
            
            UndergroundAreaLoader.SyncDataSend(identity);
            break;
            
        case ClientReadyEventTypeID:
            ClientReadyEventParams readyParams;
            Class.CastTo(readyParams, params);
            identity = readyParams.param1;
            Class.CastTo(player, readyParams.param2);
            if (!player)
            {
                Debug.Log("ClientReadyEvent: Player is empty");
                return;
            }
            
            OnClientReadyEvent(identity, player);
            InvokeOnConnect(player, identity);
            // Send list of players at all clients
            SyncEvents.SendPlayerList();
            ControlPersonalLight(player);
            SyncGlobalLighting(player);
            
            UndergroundAreaLoader.SyncDataSend(identity);
            break;
                    
        case ClientRespawnEventTypeID:
            ClientRespawnEventParams respawnParams;
            Class.CastTo(respawnParams, params);
            identity = respawnParams.param1;
            Class.CastTo(player, respawnParams.param2);
            if (!player)
            {
                Debug.Log("ClientRespawnEvent: Player is empty");
                return;
            }
            
            OnClientRespawnEvent(identity, player);
            break;
            
        case ClientReconnectEventTypeID:
            ClientReconnectEventParams reconnectParams;
            Class.CastTo(reconnectParams, params);
            
            identity = reconnectParams.param1;
            Class.CastTo(player, reconnectParams.param2);
            if (!player)
            {
                Debug.Log("ClientReconnectEvent: Player is empty");
                return;
            }
            
            OnClientReconnectEvent(identity, player);
            break;
        
        case ClientDisconnectedEventTypeID:
            ClientDisconnectedEventParams discoParams;
            Class.CastTo(discoParams, params);      
            
            identity = discoParams.param1;
            Class.CastTo(player, discoParams.param2);           
            int logoutTime = discoParams.param3;
            bool authFailed = discoParams.param4;
 
            if (!player)
            {
                Debug.Log("ClientDisconnectenEvent: Player is empty");
                return;
            }
            
            OnClientDisconnectedEvent(identity, player, logoutTime, authFailed);
            break;
            
        case LogoutCancelEventTypeID:
            LogoutCancelEventParams logoutCancelParams;
            
            Class.CastTo(logoutCancelParams, params);               
            Class.CastTo(player, logoutCancelParams.param1);
            identity = player.GetIdentity();
            if (identity)
            {
                // disable reconnecting to old char
                // g_Game.RemoveFromReconnectCache(identity.GetId());
                Print("[Logout]: Player " + identity.GetId() + " cancelled"); 
            }
            else
            {
                Print("[Logout]: Player cancelled"); 
            }
            m_LogoutPlayers.Remove(player);
            m_NewLogoutPlayers.Remove(player);
            break;
        }
    }

Перекрестные ссылки Class::CastTo(), ClientDisconnectedEventTypeID, ClientNewEventTypeID, ClientPrepareEventTypeID, ClientReadyEventTypeID, ClientReconnectEventTypeID, ClientRespawnEventTypeID, ControlPersonalLight(), PlayerIdentityBase::GetId(), InvokeOnConnect(), Debug::Log(), LogoutCancelEventTypeID, m_LogoutPlayers, m_NewLogoutPlayers, OnClientDisconnectedEvent(), OnClientNewEvent(), OnClientPrepareEvent(), OnClientReadyEvent(), OnClientReconnectEvent(), OnClientRespawnEvent(), Print(), SyncEvents::SendPlayerList(), CfgBunkerBroadcastHandler::SyncDataSend(), CfgPlayerRestrictedAreaHandler::SyncDataSend(), UndergroundAreaLoader::SyncDataSend(), CfgGameplayHandler::SyncDataSendEx() и SyncGlobalLighting().