OnFinishProgressServer()

override void ActionDigInStash::OnFinishProgressServer ( ActionData action_data )

inlineprivate

См. определение в файле ActionDigInStash.c строка 131

    {
        EntityAI targetEntity = EntityAI.Cast(action_data.m_Target.GetObject());
        if (!targetEntity)
        {
            ErrorEx("Cannot get entity=" + targetEntity);
            return;
        }
        
        InventoryLocation targetIL = new InventoryLocation();
        if (!targetEntity.GetInventory().GetCurrentInventoryLocation(targetIL))
        {
            ErrorEx("Cannot get inventory location of entity=" + targetEntity);
            return;
        }
        
        EntityAI entityToCheck = targetEntity;
        if (targetEntity.GetInventory().IsInCargo())
            entityToCheck = action_data.m_Player;
        
        int liquidType;
        string surfaceType;
        g_Game.SurfaceUnderObject(entityToCheck, surfaceType, liquidType);
        string undergroundStashType;
        
        g_Game.GetSurfaceDigPile(surfaceType, undergroundStashType);
        
        if (undergroundStashType == "")
            undergroundStashType =  "UndergroundStash";
        
        UndergroundStash stash = UndergroundStash.Cast(g_Game.CreateObjectEx(undergroundStashType, targetEntity.GetPosition(), ECE_PLACE_ON_SURFACE));  
        if (stash)
        {
            ClearActionJuncture(action_data);
            stash.PlaceOnGround();
            InventoryLocation ilj = new InventoryLocation;
            stash.GetInventory().GetCurrentInventoryLocation(ilj);
        
            if (GameInventory.LocationCanRemoveEntity(targetIL))
            {           
                if (!g_Game.IsMultiplayer())
                {
                    ClearInventoryReservationEx(action_data);
                    action_data.m_Player.LocalTakeEntityToTargetCargo(stash, targetEntity);
                }
                else 
                    action_data.m_Player.ServerTakeEntityToTargetCargo(stash, targetEntity);
            }
            else
            {
                Debug.Log(string.Format("Cannot remove entity=%1 obj from current location=%2", targetEntity, InventoryLocation.DumpToStringNullSafe(targetIL)));
            }
        }
        else
        {
            ErrorEx("Stash not spawned!");
        }
        
        //Apply tool damage
        MiscGameplayFunctions.DealEvinronmentAdjustedDmg(action_data.m_MainItem, action_data.m_Player, 10);
    }

Перекрестные ссылки ActionData, ActionBase::ClearActionJuncture(), ActionBase::ClearInventoryReservationEx(), InventoryLocation::DumpToStringNullSafe(), ECE_PLACE_ON_SURFACE, ErrorEx, g_Game, GameInventory::LocationCanRemoveEntity() и Debug::Log().