ApplyWetnessToItem()

void Environment::ApplyWetnessToItem ( ItemBase pItem )

inlineprotected

См. определение в файле Environment.c строка 662

    {
        if (pItem)
        {
            ItemBase parentItem;
            bool isParentWet            = false;
            bool parentContainsLiquid   = false;
            InventoryLocation iLoc      = new InventoryLocation();
 
            if (pItem.GetInventory().GetCurrentInventoryLocation(iLoc))
            {
                EntityAI parent = iLoc.GetParent();
                if (parent)
                {
                    parentItem = ItemBase.Cast(parent);
                    if (parentItem)
                    {
                        if (parentItem.GetWet() >= GameConstants.STATE_SOAKING_WET)
                            isParentWet = true;
 
                        if ((parentItem.GetLiquidType() != 0) && (parentItem.GetQuantity() > 0))
                            parentContainsLiquid = true;
                    }
                    else
                        isParentWet = true;
                    
                    if ((pItem.GetWet() > m_ItemsWetnessMax) && (parent == m_Player))
                        m_ItemsWetnessMax = pItem.GetWet();
                }
            }
 
            if (isParentWet || parentContainsLiquid)
            {
                float soakingCoef = 0;
                if (parentContainsLiquid)
                {
                    soakingCoef = pItem.GetSoakingIncrement("parentWithLiquid");
                    LogDryWetProcess(string.Format("%1 (soak coef=%2/s, current wetness=%3) [parent contains liquid]", pItem.GetDisplayName(), soakingCoef / GameConstants.ENVIRO_TICK_RATE, pItem.GetWet()), parentItem != null);
                }
                else if (isParentWet && parentItem)
                {
                    if (pItem.GetWet() < parentItem.GetWet())
                        soakingCoef = GetWetDelta();
 
                    LogDryWetProcess(string.Format("%1 (soak coef=%2/s, current wetness=%3) [parent wet]", pItem.GetDisplayName(), soakingCoef / GameConstants.ENVIRO_TICK_RATE, pItem.GetWet()), parentItem != null);
                }
                else
                {
                    soakingCoef = GetWetDelta();
                    LogDryWetProcess(string.Format("%1 (soak coef=%2/s, current wetness=%3) [normal]", pItem.GetDisplayName(), soakingCoef / GameConstants.ENVIRO_TICK_RATE, pItem.GetWet()), parentItem != null);
                }
 
                pItem.AddWet(soakingCoef);
 
                if (pItem.GetInventory().GetCargo())
                {
                    int inItemCount = pItem.GetInventory().GetCargo().GetItemCount();
                    for (int i = 0; i < inItemCount; ++i)
                    {
                        ItemBase inItem;
                        if (Class.CastTo(inItem, pItem.GetInventory().GetCargo().GetItem(i)))
                            ApplyWetnessToItem(inItem);
                    }
                }
                
                int attCount = pItem.GetInventory().AttachmentCount();
                if (attCount > 0)
                {
                    for (int attIdx = 0; attIdx < attCount; ++attIdx)
                    {
                        EntityAI attachment = pItem.GetInventory().GetAttachmentFromIndex(attIdx);
                        ItemBase itemAtt = ItemBase.Cast(attachment);
                        if (itemAtt)
                            ApplyWetnessToItem(itemAtt);
                    }
                }
            }
        }
    }

Перекрестные ссылки ApplyWetnessToItem(), Class::CastTo(), GameConstants::ENVIRO_TICK_RATE, InventoryLocation::GetParent(), GetWetDelta(), LogDryWetProcess(), m_ItemsWetnessMax, m_Player и GameConstants::STATE_SOAKING_WET.

Используется в ApplyWetnessToItem() и ProcessItemsWetness().