OnStoreLoad()

override bool Weapon::OnStoreLoad ( ParamsReadContext ctx, int version )

inlineprotected

См. определение в файле Weapon_Base.c строка 487

    {
        if ( !super.OnStoreLoad(ctx, version) )
            return false;
        
        
        if (version >= 113)
        {
            int current_muzzle = 0;
            if (!ctx.Read(current_muzzle))
            {
                Error("Weapon.OnStoreLoad " + this + " cannot read current muzzle!");
                return false;
            }
            
            if (current_muzzle >= GetMuzzleCount() || current_muzzle < 0)
                Error("Weapon.OnStoreLoad " + this + " trying to set muzzle index " + current_muzzle + " while it only has " + GetMuzzleCount() + " muzzles!");
            else
                SetCurrentMuzzle(current_muzzle);
        }       
        
        if (version >= 105)
        {
            int mode_count = 0;
            if (!ctx.Read(mode_count))
            {
                Error("Weapon.OnStoreLoad " + this + " cannot read mode count!");
                return false;
            }
                
            for (int m = 0; m < mode_count; ++m)
            {
                int mode = 0;
                if (!ctx.Read(mode))
                {
                    Error("Weapon.OnStoreLoad " + this + " cannot read mode[" + m + "]");
                    return false;
                }
                
                if (LogManager.IsWeaponLogEnable()) { wpnDebugPrint("[wpnfsm] " + Object.GetDebugName(this) + " OnStoreLoad - loaded muzzle[" + m + "].mode = " + mode); }
                SetCurrentMode(m, mode);
            }
        }
        
        if ( version >= 106 )
        {
            if ( !ctx.Read(m_isJammed) )
            {
                Error("Weapon.OnStoreLoad cannot load jamming state");
                return false;
            }
        }
 
        if (m_fsm)
        {
            if (!m_fsm.OnStoreLoad(ctx, version))
                return false;
            
            WeaponStableState wss = WeaponStableState.Cast(m_fsm.GetCurrentState());
            if (wss)
            {
                SetGroundAnimFrameIndex(wss.m_animState);
            }
            
        }
        else
        {
            int dummy = 0;
            if (!ctx.Read(dummy))
                return false;
        }
 
        return true;
    }

Перекрестные ссылки Error(), LogManager::IsWeaponLogEnable(), m_fsm, m_isJammed, Serializer::Read() и wpnDebugPrint().