FillInnerMagazine()

bool Weapon::FillInnerMagazine ( string ammoType = "", int flags = WeaponWithAmmoFlags.CHAMBER )

inlineprotected

Try to fill the inner magazine.

Аргументы

[in]

ammoType

string The ammo to load, passing in empty string will select random

Заметки

It is best to fill in the actual 'ammo', as in the ones usually prefixed by 'Bullet_', to skip searching for it

Аргументы

[in]

flags

int Setup flags, please read WeaponWithAmmoFlags

Возвращает

Whether any ammo was added to the gun or not

См. определение в файле Weapon_Base.c строка 827

    {
        // Don't try to fill it when there are none
        if (!HasInternalMagazine(-1))
            return false;
    
        // Make sure the given ammoType is actually useable
        if (ammoType != "")
        {
            if (!AmmoTypesAPI.MagazineTypeToAmmoType(ammoType, ammoType))
                return false;
        }
        
        
        bool didSomething = false;      
        int muzzCount = GetMuzzleCount();
        
        bool ammoRng = ammoType == "";
        bool ammoFullRng = ammoRng && (flags & WeaponWithAmmoFlags.AMMO_MAG_RNG);
        
        // No full RNG flag, so pick one random and use only this one
        if (ammoRng && !ammoFullRng)
            ammoType = GetRandomChamberableAmmoTypeName(0);
        
        // Fill the internal magazine
        for (int i = 0; i < muzzCount; ++i)
        {
            int ammoCount = GetInternalMagazineMaxCartridgeCount(i);
            
            // Decide random quantity when enabled
            if ( flags & WeaponWithAmmoFlags.QUANTITY_RNG )
                ammoCount = Math.RandomIntInclusive(0, ammoCount);
            
            // Only do the things when there is actually ammo to fill
            if (ammoCount > 0)
            {
                // Push in the cartridges
                for (int j = 0; j < ammoCount; ++j)
                {
                    // Full random, decide a new one for every cartridge
                    if ( ammoFullRng )
                        ammoType = GetRandomChamberableAmmoTypeName(i);
                    
                    PushCartridgeToInternalMagazine(i, 0, ammoType);
                    didSomething = true;
                }
            }
        }
        
        // Call the chamber method if asked for
        bool chamber = (flags & WeaponWithAmmoFlags.CHAMBER) || (flags & WeaponWithAmmoFlags.CHAMBER_RNG);
        if (chamber && FillChamber(ammoType, flags))
        {
            didSomething = true;
        }
        
        // Does not need any FSM fixing, FSM does not care about inner magazines
        
        return didSomething;
    }

Перекрестные ссылки FillChamber(), AmmoTypesAPI::MagazineTypeToAmmoType() и Math::RandomIntInclusive().

Используется в SpawnAmmo().