Refresh()

void Refresh ( bool hide_selector = true )

protected

См. определение в файле RadialMenu.c строка 228

    {
        int item_cards_count = GetItemCardsCount();
        if (item_cards_count > 0)
            m_AngleRadOffset = 2 * Math.PI / item_cards_count;        
        float angle_rad = -Math.PI / 2;
        
        //--PARAM top offset--
        if (m_OffsetFromTop != 0)
        {
            angle_rad = angle_rad + m_OffsetFromTop;
        }
        //--------------------
        
        //delete all delimiters
        Widget delimiters_panel = m_Parent.FindAnyWidget(RADIAL_DELIMITER_CONTAINER);
        if (delimiters_panel)
        {
            Widget del_child = delimiters_panel.GetChildren();
            while (del_child)
            {
                Widget child_to_destroy1 = del_child;
                del_child = del_child.GetSibling();
                
                delete child_to_destroy1;
            }
        }
        
        //Position item cards, crate radial delimiters
        Widget item_cards_panel = m_Parent.FindAnyWidget(RADIAL_ITEM_CARD_CONTAINER);
        Widget item_card = item_cards_panel.GetChildren();
        
        //get radius
        float original_r = GetRadius();
        float item_cards_r = original_r;
        
        //--PARAM top offset--....
        if (m_ItemCardRadiusOffset != 0)
        {
            item_cards_r = item_cards_r * m_ItemCardRadiusOffset;
            if (item_cards_r < 0) item_cards_r = 0;             //min radius is 0
        }
        
        m_RadialItemCards.Clear();
        for (int i = 0; i < item_cards_count; ++i)
        {
            //position item cards
            if (item_card)
            {
                //creates circle from simple widget items
                float pos_x = item_cards_r * Math.Cos(angle_rad);
                float pos_y = item_cards_r * Math.Sin(angle_rad);
                
                pos_x = pos_x / original_r;
                pos_y = pos_y / original_r;
                
                item_card.SetPos(pos_x, pos_y);
                
                //store item card
                m_RadialItemCards.Insert(item_card, angle_rad);
                
                //get next child
                item_card = item_card.GetSibling();
            }
            //-------------------------
            
            //create delimiter
            if (item_cards_count > 1 && delimiters_panel && m_DelimiterLayout)
            {
                Widget delimiter_widget = GetGame().GetWorkspace().CreateWidgets(m_DelimiterLayout, delimiters_panel);
                float delim_angle_rad = angle_rad + (m_AngleRadOffset / 2);
                delimiter_widget.SetPos(0, 0);
                delimiter_widget.SetRotation(0, 0, GetAngleInDegrees(delim_angle_rad) + 90);
            }
                        
            //calculate next angle
            angle_rad += m_AngleRadOffset;
        }
        
        //hide selector on refresh
        if (hide_selector)
        {
            HideRadialSelector();
        }
    }

Перекрестные ссылки Math::Cos(), WorkspaceWidget::CreateWidgets(), GetAngleInDegrees(), GetGame(), GetItemCardsCount(), GetRadius(), CGame::GetWorkspace(), HideRadialSelector(), m_AngleRadOffset, m_DelimiterLayout, m_ItemCardRadiusOffset, m_OffsetFromTop, m_Parent, m_RadialItemCards, Math::PI, RADIAL_DELIMITER_CONTAINER, RADIAL_ITEM_CARD_CONTAINER и Math::Sin().