OnInput()

override void Car::OnInput ( float dt )

inlineprotected

См. определение в файле CarScript.c строка 1041

    {
        super.OnInput(dt);
        
#ifdef DIAG_DEVELOPER
        if (m_eDebugMode == ECarDebugMode.NONE)
            return;
        
        float currentRPM = EngineGetRPM();
        if (currentRPM < EngineGetRPMIdle())
        {
            if (currentRPM < 1.0 && EngineIsOn())
            {
                EngineStop();
            }
            else if (!EngineIsOn())
            {
                EngineStart();
            }
              
            return;
        }
        
        float currentSpeed = GetSpeedometer();
        
        float longitudinalWanted = 0.0;
        float throttleWanted = 0.0;
        float steeringWanted = 0.0;
        
        bool attemptSpeed = false;
        float speedWanted = 0;
        
        string text = "";
        
        switch (m_eDebugMode)
        {
        case ECarDebugMode.FORWARD_10:
            attemptSpeed = true;
            speedWanted = 3;
            break;
        case ECarDebugMode.FORWARD_50:
            attemptSpeed = true;
            speedWanted = 50;
            break;
        case ECarDebugMode.RANDOM_DRIVING:
            attemptSpeed = true;
            
            m_DebugParams.param1 -= dt;
            if (m_DebugParams.param1 <= 0)
            {
                m_DebugParams.param1 = Math.RandomFloatInclusive(0.01, 1.0);
                                
                speedWanted = speedWanted + Math.RandomFloatInclusive(-25, 25);
                
                speedWanted = Math.Clamp(speedWanted, -20, 100);
                
                steeringWanted = Math.RandomFloatInclusive(-1, 1);
                
                float steeringWantedSign = (steeringWanted > 0) - (steeringWanted < 0);
                steeringWanted = steeringWantedSign * Math.Pow(Math.AbsFloat(steeringWanted), 0.5);
                
                if (Math.AbsFloat(speedWanted - currentSpeed) > 15)
                {
                    steeringWanted *= 0.1;
                }
                
                m_DebugParams.param2 = steeringWanted;
                m_DebugParams.param3 = speedWanted;
            }
            
            steeringWanted = m_DebugParams.param2;
            speedWanted = m_DebugParams.param3;
        
            text += "\nTarget Steering: " + steeringWanted;
            text += "\nTarget Speed: " + speedWanted;
            text += "\nCurrent Speed: " + currentSpeed;
 
            break;
        case ECarDebugMode.PREDEFINED_PATH:
            attemptSpeed = true;
            speedWanted = 50;
            break;
        }
        
        if (!GetGame().IsDedicatedServer())
        {
            vector transform[4];
            GetTransform(transform);
            m_DebugText = DebugTextWorldSpace.CreateInWorld(text, DebugTextFlags.DEFAULT | DebugTextFlags.FACE_CAMERA, transform, 1.0);
        }
 
        if (attemptSpeed)
        {
            longitudinalWanted = speedWanted - currentSpeed;
    
            if (speedWanted > 0.1 && currentSpeed > 0.1)
            {
                longitudinalWanted = Math.Max(longitudinalWanted, 0.1);
            }
            else if (speedWanted < 0.1 && currentSpeed < 0.1)
            {
                longitudinalWanted = Math.Min(longitudinalWanted, -0.1);
            }
        }
        
        float hillFactor = GetOrientation()[1] / 10.0;
        hillFactor += 1.0;
        hillFactor = Math.Clamp(hillFactor, 0.5, 5.0);
        
        throttleWanted = (EngineGetRPMMin() - EngineGetRPM()) / (EngineGetRPMMin() - EngineGetRPMRedline());
        throttleWanted = 1.0 - throttleWanted;
        throttleWanted *= Math.AbsFloat(longitudinalWanted);
        throttleWanted *= hillFactor;
        throttleWanted = Math.Clamp(throttleWanted, 0.0, 1.0); 
                
        bool isManual = GearboxGetType() == CarGearboxType.MANUAL;
        bool isReverse = GetGear() == CarGear.REVERSE;
        
        if (isManual)
        {
            float thrustWantedAbs = Math.AbsFloat(throttleWanted);
            
            /*
            wtf enforce script?
            bool override1 = false;
            
            if (attemptSpeed)
            {
                if (speedWanted < 0 && currentSpeed < 10)
                {
                    ShiftTo(CarGear.REVERSE);
                    override1 = true;
                }
                else if (speedWanted <= 1)
                {
                    ShiftTo(CarGear.NEUTRAL);
                    override1 = true;
                }
            }
            */
 
            if (currentRPM > EngineGetRPMRedline() * 0.8)
            {
                if (thrustWantedAbs > 0.1)
                {
                    ShiftUp();
                }
            }
            else if (GetGear() > CarGear.FIRST && thrustWantedAbs < 0.1)
            {
                ShiftDown();
            }
            else if (GetGear() < CarGear.FIRST || (throttleWanted > 0.0 && Math.AbsFloat(currentSpeed) < 5.0))
            {
                ShiftTo(CarGear.FIRST);
            }
        }
        
        SetThrottle(throttleWanted);
        SetSteering(steeringWanted);
        SetBrake(0.1);
        SetHandbrake(0.0);
        SetBrakesActivateWithoutDriver(false);
#endif
    }

Перекрестные ссылки Math::AbsFloat(), Math::Clamp(), DebugTextWorldSpace::CreateInWorld(), EngineGetRPM(), EngineGetRPMIdle(), EngineGetRPMMin(), EngineGetRPMRedline(), EngineIsOn(), EngineStart(), EngineStop(), GearboxGetType(), GetGame(), GetGear(), GetOrientation(), GetSpeedometer(), Math::Max(), Math::Min(), Math::Pow(), Math::RandomFloatInclusive(), SetBrake(), SetHandbrake(), SetSteering(), SetThrottle(), ShiftDown(), ShiftTo() и ShiftUp().