Consume() [2/2]

bool ManBase::Consume ( PlayerConsumeData data )

inlineprivate

См. определение в файле PlayerBase.c строка 7344

    {
        PluginTransmissionAgents plugin = PluginTransmissionAgents.Cast(GetPlugin(PluginTransmissionAgents));
        WorldData worldData = g_Game.GetMission().GetWorldData();
        int pollution = worldData.GetPollution();
        float temperature = 0;
        
        if (data.m_Type == EConsumeType.ENVIRO_POND || data.m_Type == EConsumeType.ENVIRO_WELL || data.m_Type == EConsumeType.ENVIRO_SNOW)
        {
            if (data.m_Type != EConsumeType.ENVIRO_WELL)
            {
                if (pollution & EPollution.HEAVYMETAL)
                    data.m_Agents = data.m_Agents | eAgents.HEAVYMETAL;
 
                if (data.m_Type == EConsumeType.ENVIRO_POND)
                    data.m_Agents = data.m_Agents | eAgents.CHOLERA;
            }
 
            temperature = worldData.GetLiquidTypeEnviroTemperature(data.m_LiquidType);
            m_PlayerStomach.AddToStomach(Liquid.GetLiquidClassname(LIQUID_WATER), data.m_Amount, 0 , data.m_Agents, temperature);
            
            return true;
        }
        
        Edible_Base edibleItem = Edible_Base.Cast(data.m_Source);
        if (!edibleItem || !edibleItem.CanBeConsumed())
            return false;
 
        if (data.m_Type == EConsumeType.ITEM_SINGLE_TIME || data.m_Type == EConsumeType.ITEM_CONTINUOUS)
        {
            data.m_Agents = edibleItem.FilterAgents(data.m_Agents | edibleItem.GetAgents());
            temperature = edibleItem.GetTemperature();
 
            if (data.m_Type == EConsumeType.ITEM_SINGLE_TIME)
                plugin.TransmitAgents(edibleItem, this, AGT_UACTION_CONSUME, data.m_Amount);
 
            if (edibleItem.IsLiquidContainer())
            {
                int liquidType = edibleItem.GetLiquidType();
                string liquidClassName = Liquid.GetLiquidClassname(liquidType);
                if (liquidClassName.Length() == 0)
                    Error("Error! Trying to add unknown liquid to stomach with item=" + Object.GetDebugName(edibleItem) + " data.m_Type=" + data.m_Type + " liquid_type=" + liquidType);
 
                m_PlayerStomach.AddToStomach(liquidClassName, data.m_Amount, 0, data.m_Agents, temperature);
            }
            else
            {
                int foodStageType;
                if (edibleItem.GetFoodStage())
                    foodStageType = edibleItem.GetFoodStage().GetFoodStageType();
 
                m_PlayerStomach.AddToStomach(data.m_Source.GetType(), data.m_Amount, foodStageType, data.m_Agents, temperature);
            }
 
            edibleItem.Consume(data.m_Amount, this);
 
            return true;
 
        }
 
        return false;   
    }

Перекрестные ссылки AGT_UACTION_CONSUME, Edible_Base::Consume(), Error(), Edible_Base::FilterAgents(), g_Game, Edible_Base::GetFoodStage(), WorldData::GetLiquidTypeEnviroTemperature(), GetPlugin(), WorldData::GetPollution(), string::Length(), LIQUID_WATER, PlayerConsumeData::m_Agents, PlayerConsumeData::m_Amount, PlayerConsumeData::m_LiquidType, m_PlayerStomach, PlayerConsumeData::m_Source и PlayerConsumeData::m_Type.