DeviceUpdate()

void ComponentEnergyManager::DeviceUpdate ( )

inlineprotected

См. определение в файле ComponentEnergyManager.c строка 1747

    {
        /*
        vector pos = m_ThisEntityAI.GetPosition();
        string debug_message = "Object " + m_ThisEntityAI.GetType() + "  |  Energy: " + GetEnergy() + "  |  IsAtReach: " + (IsEnergySourceAtReach(pos)).ToString();
        Print(debug_message);
        */
        
        if ( !m_IsPassiveDevice )
        {
            // 'm_ThisEntityAI' and 'this' must be checked because this method is caled from a timer
            if ( m_ThisEntityAI  &&  this  &&  IsSwitchedOn()  &&  !m_ThisEntityAI.IsRuined()  &&  CheckWetness()  &&  m_CanWork  &&  !GetGame().IsMissionMainMenu() )
            {
                bool was_powered = IsWorking();
                float consumed_energy_coef;
                // Make sure to use only as much % of energy as needed since this function can be called at random.
                
                if ( m_LastUpdateTime == 0 )
                {
                    RememberLastUpdateTime();
                    consumed_energy_coef = 1.0;
                }
                else
                {
                    float updatetime = GetCurrentUpdateTime();
                    float time = updatetime - m_LastUpdateTime;
                    consumed_energy_coef = time / 1000;
                }
                
                if (consumed_energy_coef > 0) // Prevents calling of OnWork events when no energy is consumed
                {
                    m_LastUpdateTime = GetCurrentUpdateTime();
                    float consume_energy = GetEnergyUsage() * consumed_energy_coef;
                    bool has_consumed_enough = true;
                    
                    if (GetGame().IsServer() || !GetGame().IsMultiplayer()) // single player or server side multiplayer
                        has_consumed_enough = ConsumeEnergy( consume_energy );
                    
                    SetPowered( has_consumed_enough );
                    
                    if ( has_consumed_enough )
                    {
                        if ( !was_powered )
                        {
                            m_CanStopWork = true;
                            WakeUpWholeBranch(m_ThisEntityAI);
                            GetGame().GameScript.CallFunction(m_ThisEntityAI, "OnWorkStart", NULL, 0);
                            UpdateCanWork();
                        }
                        
                        OnWork( consume_energy );
                    }
                    else
                    {
                        if ( was_powered )
                        {
                            if (m_CanStopWork)
                            {
                                m_CanStopWork = false;
                                ClearLastUpdateTime();
                                GetGame().GameScript.CallFunction(m_ThisEntityAI, "OnWorkStop", NULL, 0); // This event is called only once when the device STOPS being powered
                                UpdateCanWork();
                                
                                if (m_AutoSwitchOff)
                                {
                                    SwitchOff(); 
                                }
                            }
                        }
                        
                        StopUpdates();
                    }
                }
                else
                {
                    ClearLastUpdateTime();
                }
            }
            else if (this && m_ThisEntityAI)
            {
                SetPowered( false );
                StopUpdates();
                
                if (m_CanStopWork)
                {
                    m_CanStopWork = false;
                    ClearLastUpdateTime();
                    GetGame().GameScript.CallFunction(m_ThisEntityAI, "OnWorkStop", NULL, 0); // This event is called only once when the device STOPS being powered
                    UpdateCanWork();
                    
                    if (m_AutoSwitchOff)
                    {
                        SwitchOff(); 
                    }
                }
            }
        }
    }

Перекрестные ссылки ScriptModule::CallFunction(), CheckWetness(), ClearLastUpdateTime(), ConsumeEnergy(), CGame::GameScript, GetCurrentUpdateTime(), GetEnergyUsage(), GetGame(), IsSwitchedOn(), IsWorking(), m_AutoSwitchOff, m_CanStopWork, m_CanWork, m_IsPassiveDevice, m_LastUpdateTime, Component::m_ThisEntityAI, OnWork(), RememberLastUpdateTime(), SetPowered(), StopUpdates(), SwitchOff(), UpdateCanWork() и WakeUpWholeBranch().

Используется в SetPassiveState(), SwitchOff() и SwitchOn().