UpdateLightsClient()

void UpdateLightsClient ( int newGear = -1 )

protected

См. определение в файле CarScript.c строка 1850

    {
        int gear;
        
        if (newGear == -1)
        {
            gear = GetGear();
        }
        else
        {
            gear = newGear;
        }
        
        if (m_HeadlightsOn)
        {
            if (!m_Headlight && m_HeadlightsState != CarHeadlightBulbsState.NONE)
            {
                m_Headlight = CreateFrontLight();
            }
            
            if (m_Headlight)
            {
                switch (m_HeadlightsState)
                {
                case CarHeadlightBulbsState.LEFT:
                    m_Headlight.AttachOnMemoryPoint(this, m_LeftHeadlightPoint, m_LeftHeadlightTargetPoint);
                    m_Headlight.SegregateLight();
                    break;
                case CarHeadlightBulbsState.RIGHT:
                    m_Headlight.AttachOnMemoryPoint(this, m_RightHeadlightPoint, m_RightHeadlightTargetPoint);
                    m_Headlight.SegregateLight();
                    break;
                case CarHeadlightBulbsState.BOTH:
                    vector local_pos_left = GetMemoryPointPos(m_LeftHeadlightPoint);
                    vector local_pos_right = GetMemoryPointPos(m_RightHeadlightPoint);
                    
                    vector local_pos_middle = (local_pos_left + local_pos_right) * 0.5;
                    m_Headlight.AttachOnObject(this, local_pos_middle);
                    m_Headlight.AggregateLight();
                    break;
                default:
                    m_Headlight.FadeOut();
                    m_Headlight = null;
                }
            }
        }
        else
        {
            if (m_Headlight)
            {
                m_Headlight.FadeOut();
                m_Headlight = null;
            }
        }
            
        // brakes & reverse
        switch (gear)
        {
            case CarGear.REVERSE:
            case CarAutomaticGearboxMode.R:
                if (m_BrakesArePressed)
                    m_RearLightType = CarRearLightType.BRAKES_AND_REVERSE;
                else
                    m_RearLightType = CarRearLightType.REVERSE_ONLY;
                break;
            default:
                if (m_BrakesArePressed)
                    m_RearLightType = CarRearLightType.BRAKES_ONLY;
                else
                    m_RearLightType = CarRearLightType.NONE;
        }
 
        //Debug.Log(string.Format("m_BrakesArePressed=%1, m_RearLightType=%2", m_BrakesArePressed.ToString(), EnumTools.EnumToString(CarRearLightType, m_RearLightType)));
 
        if (!m_RearLight && m_RearLightType != CarRearLightType.NONE && m_HeadlightsState != CarHeadlightBulbsState.NONE)
        {
            if (EngineIsOn() || m_RearLightType == CarRearLightType.BRAKES_ONLY || m_RearLightType == CarRearLightType.BRAKES_AND_REVERSE)
            {   
                m_RearLight = CreateRearLight();
                vector localPos = GetMemoryPointPos(m_ReverseLightPoint);
                m_RearLight.AttachOnObject(this, localPos, "180 0 0");
            }
        }
 
        // rear lights
        if (m_RearLight && m_RearLightType != CarRearLightType.NONE && m_HeadlightsState != CarHeadlightBulbsState.NONE)
        {
            switch (m_RearLightType)
            {
                case CarRearLightType.BRAKES_ONLY:
                    BrakesRearLight();
                    break;
                case CarRearLightType.REVERSE_ONLY:
                    if (EngineIsOn())
                        ReverseRearLight();
                    else
                        NoRearLight();
 
                    break;
                case CarRearLightType.BRAKES_AND_REVERSE:
                    if (EngineIsOn())
                        BrakeAndReverseRearLight();
                    else
                        BrakesRearLight();
    
                    break;
                default:
                    NoRearLight();
            }
        }
        else
        {
            if (m_RearLight)
            {
                NoRearLight();
            }
        }
    }

Перекрестные ссылки BrakeAndReverseRearLight(), BrakesRearLight(), CarScript::CreateFrontLight(), CarScript::CreateRearLight(), m_BrakesArePressed, m_Headlight, m_HeadlightsOn, m_HeadlightsState, m_LeftHeadlightPoint, m_LeftHeadlightTargetPoint, m_RearLight, m_RearLightType, m_ReverseLightPoint, m_RightHeadlightPoint, m_RightHeadlightTargetPoint, NoRearLight() и ReverseRearLight().

Используется в UpdateLights().