GetRaycastedHitZone()

string AreaDamageBase::GetRaycastedHitZone ( Object victim, array< string > raycast_sources_str )

inlineprotected

См. определение в файле AreaDamage.c строка 162

    {
        
        // Vertical raycast start positions:    Center,      North East,    North West,    South East,  South West
        //vector raycast_sources[5] = {"0.0 0.1 0.0", "0.2 0.1 0.2", "-.2 0.1 0.2", "0.2 0.1 -.2", "-.2 0.1 -.2"};
        
        string hitzone;
        vector contact_pos;
        vector contact_dir;
        int contactComponent;
        bool isSteppedOn = false;
        
        array<vector> raycast_sources = new array<vector>;
        ref set<Object> victims = new set<Object>;
 
        // convert Array of string to array of Vectors
        for ( int v = 0; v < raycast_sources_str.Count(); ++v)
        {
            raycast_sources.Insert(raycast_sources_str[v].ToVector());
        }
        
        for ( int i = 0; i < raycast_sources.Count(); ++i )
        {
            vector raycast_start_pos = m_AreaDamageTrigger.ModelToWorld( raycast_sources.Get(i) );
            vector raycast_end_pos = "0 0.5 0" + raycast_start_pos;
            
            //#ifdef DEVELOPER
            //Debug.DrawArrow( raycast_start_pos, raycast_end_pos );
            //#endif
            DayZPhysics.RaycastRV( raycast_start_pos, raycast_end_pos, contact_pos, contact_dir, contactComponent, victims , null, m_AreaDamageTrigger, true, false, ObjIntersectIFire);
            
            for ( int j = 0; j < victims.Count(); ++j )
            {
                Object contact_obj = victims.Get(j);
                
                if ( contact_obj.IsAnyInherited(m_DamageableTypes) )
                {
                    isSteppedOn = true;
                    break;
                }
            }
            
            if ( isSteppedOn )
            {
                EntityAI eai = EntityAI.Cast(victim);
                if ( eai )
                {
                    hitzone = eai.GetDamageZoneNameByComponentIndex(contactComponent);
                    break;
                }
            }
        }
        
        if ( isSteppedOn )
        {
            return hitzone;
        }
        else
        {
            // Damage random leg since we don't know what part of player's body was caught in the trap.
            string dmg_zone_rnd = "LeftFoot";
            if ( Math.RandomIntInclusive(0, 1) == 1 )
                dmg_zone_rnd = "RightFoot";
            return dmg_zone_rnd;
        }
    }

Перекрестные ссылки m_AreaDamageTrigger, Math::RandomIntInclusive() и DayZPhysics::RaycastRV().

Используется в EvaluateDamage().