GetMagazineToReload()

EntityAI ManBase::GetMagazineToReload ( EntityAI weapon )

inlineprotected

См. определение в файле PlayerBase.c строка 4895

    {
        Weapon_Base weapon_base = Weapon_Base.Cast(weapon);
        WeaponManager weapon_manager = GetWeaponManager();
        EntityAI magazine_to_reload;
        
        EntityAI ammo_magazine;             //magazine
        int last_ammo_magazine_count;
        int ammo_magazine_count;
        
        EntityAI ammo_pile;                 //ammo pile
        int last_ammo_pile_count;
        int ammo_pile_count;
        
        //Get all magazines in (player) inventory
        GameInventory inventory = GetInventory();
        int nAttachment = inventory.AttachmentCount();
        for (int att_i = 0; att_i < nAttachment; ++att_i)
        {
            EntityAI attachment = inventory.GetAttachmentFromIndex(att_i);
            ref CargoBase attachment_cargo = attachment.GetInventory().GetCargo();
            
            if (attachment_cargo)
            {
                int nAttachmentCargoItem = attachment_cargo.GetItemCount();
                for (int cgo_i = 0; cgo_i < nAttachmentCargoItem; ++cgo_i)
                {
                    EntityAI cargo_item = attachment_cargo.GetItem(cgo_i);
                    
                    //check for proper magazine
                    if (cargo_item.IsMagazine())
                    {
                        Magazine magazine = Magazine.Cast(cargo_item);
                        ammo_pile_count = magazine.GetAmmoCount();
                        
                        //magazines (get magazine with max ammo count)
                        if (weapon_manager.CanAttachMagazine(weapon_base, magazine) || weapon_manager.CanSwapMagazine(weapon_base, magazine))
                        {
                            if (ammo_pile_count > 0)
                            {
                                if (last_ammo_magazine_count == 0)
                                {
                                    ammo_magazine = magazine;
                                    last_ammo_magazine_count = ammo_pile_count;
                                }
                                else
                                {
                                    if (last_ammo_magazine_count < ammo_pile_count)
                                    {
                                        ammo_magazine = magazine;
                                        last_ammo_magazine_count = ammo_pile_count;
                                    }
                                }
                            }
                        }   
                        //bullets (get ammo pile with min ammo count)
                        else if (weapon_manager.CanLoadBullet(weapon_base, magazine))
                        {
                            if (ammo_pile_count > 0)
                            {
                                if (last_ammo_pile_count == 0)
                                {
                                    ammo_pile = magazine;
                                    last_ammo_pile_count = ammo_pile_count;
                                }
                                else
                                {
                                    if (last_ammo_pile_count > ammo_pile_count)
                                    {
                                        ammo_pile = magazine;
                                        last_ammo_pile_count = ammo_pile_count;
                                    }
                                }
                            }
                        }                           
                    }
                }
            }
        }
 
        //prioritize magazine
        if (ammo_magazine)
        {
            return ammo_magazine;       
        }
        
        return ammo_pile;
    }

Перекрестные ссылки GameInventory::AttachmentCount(), WeaponManager::CanAttachMagazine(), WeaponManager::CanLoadBullet(), WeaponManager::CanSwapMagazine(), GameInventory::GetAttachmentFromIndex() и GetWeaponManager().

Используется в QuickReloadWeapon().