GetItemDesc()

string ActionTargetsCursor::GetItemDesc ( ActionBase action )

inlineprotected

См. определение в файле ActionTargetsCursor.c строка 742

    {
        string desc = "";
        Object tgObject = m_DisplayInteractTarget;
        if (!tgObject && m_Target)
        {
            tgObject = m_Target.GetObject();
        }
        
        if (tgObject)
        {
            //BreakOut if item is ruined
            Object tgParent = m_Target.GetParent();
            if (!tgObject.IsAlive())
            {
                //Fetch parent item name if one is present
                if (!tgParent || tgObject.DisplayNameRuinAttach())
                    desc = tgObject.GetDisplayName();
                else
                    desc = tgParent.GetDisplayName();
                return desc;
            }
            
            EntityAI targetEntity;
            
            if (tgParent && (tgParent.IsItemBase() || tgParent.IsTransport() || tgParent.CanUseConstruction()))
            {
                targetEntity = EntityAI.Cast(tgParent);
            }
            
            if (tgObject.IsItemBase() || tgObject.IsTransport() || tgObject.CanUseConstruction())
            {
                targetEntity = EntityAI.Cast(tgObject);
            }
            
            if (targetEntity && targetEntity.ShowZonesHealth()) //TODO: investigate, should ShowZonesHealth be in the 'description' part?
            {
                string zone = "";
                
                array<string> selections = new array<string>();
                
                //NOTE: relevant fire geometry and view geometry selection names MUST match in order to get a valid damage zone
                if (targetEntity.IsInherited(TentBase) && TentBase.Cast(targetEntity).GetState() != TentBase.PACKED)
                {
                    //This is really specific to tents, as they use proxies. Hence object must be used
                    if (DamageSystem.GetDamageZoneFromComponentName(targetEntity, tgObject.GetActionComponentName(m_Target.GetComponentIndex(), LOD.NAME_FIRE), zone))
                    {
                        desc = DamageSystem.GetDamageDisplayName(targetEntity, zone);
                    }
                }
                else
                {
                    targetEntity.GetActionComponentNameList(m_Target.GetComponentIndex(), selections, LOD.NAME_VIEW);
                    
                    //Important to get display name from component tied to multiple selections
                    for (int s = 0; s < selections.Count(); s++)
                    {
                        if (DamageSystem.GetDamageZoneFromComponentName(targetEntity, selections[s], zone))
                        {
                            desc = DamageSystem.GetDamageDisplayName(targetEntity, zone);
                        }
                    }
                }
            }
            
            //Safety check to output something to widget
            if (targetEntity && desc == "")
                desc = targetEntity.GetDisplayName();
        }
 
        return desc;
    }

Перекрестные ссылки ActionBase(), m_DisplayInteractTarget, m_Target, LOD::NAME_FIRE и LOD::NAME_VIEW.

Используется в PrepareCursorContent().