RefreshSlot()

void AttachmentCategoriesRow::RefreshSlot ( int row, int column, int slot_id, string slot_name )

inlineprotected

См. определение в файле AttachmentCategoriesRow.c строка 655

    {
        SlotsIcon icon = m_AttachmentsContainer.GetSlotsIcon(row, column);
        int slot_id_ = icon.GetSlotID();
        EntityAI item = m_Entity.GetInventory().FindAttachment( slot_id_ );
        ContainerWithCargo cont;
        
        if (!m_Entity.CanDisplayAttachmentSlot(slot_id_))
        {
            icon.Clear();
            icon.GetMainWidget().Show( false );
        }
        else if (!item)
        {
            icon.ClearRemainSelected();
                
            cont = m_AttachmentCargos.Get(slot_id_);
            if (cont)
            {
                m_AttachmentCargos.Remove(slot_id_);
                this.Remove(cont);
                ( Container.Cast( cont.m_Parent ) ).Remove( cont );
            }
            icon.GetMainWidget().Show(true);
        }
        else
        {
            icon.GetMainWidget().Show( true );
            if (icon.GetEntity() != item)
            {
                icon.Init( item );
            }
            else
            {
                icon.Refresh();
            }
            
            cont = m_AttachmentCargos.Get(slot_id_);
            if( cont && cont.GetEntity() != item)
            {
                m_AttachmentCargos.Remove(slot_id_);
                ( Container.Cast( cont.m_Parent ) ).Remove( cont );
                this.Remove(cont);
                cont = null;
            }
            
            if( !cont )
            {
                if( item.GetInventory().GetCargo() && m_AttachmentCargos )
                {
                    cont = new ContainerWithCargo( this, true );
                    cont.GetRootWidget().SetSort( m_AttachmentCargos.Count() + 10 );
                    cont.SetEntity( item );
                    cont.SetSlotIcon( icon );
                    
                    m_AttachmentCargos.Insert( slot_id_, cont );
                    icon.SetContainer(cont);
                    
                    SetOpenForSlotIcon(cont.IsOpened(),icon);
                }
            }
            
            if (cont)
            {
                icon.GetRadialIconPanel().Show( cont.IsDisplayable() );
            }
                
            string slot_name_           = InventorySlots.GetSlotName(slot_id_);
            bool draggable              = true;
            bool can_be_removed         = item.GetInventory().CanRemoveEntity();
            bool in_hands_condition     = m_Entity.GetHierarchyRoot() == GetGame().GetPlayer();
            bool in_vicinity_condition  = AttachmentsOutOfReach.IsAttachmentReachable( m_Entity, slot_name_ );
            if( m_Entity.GetInventory().GetSlotLock( slot_id_ ) && ItemManager.GetInstance().GetDraggedItem() != item )
            {
                icon.GetMountedWidget().Show( true );
                draggable = false;
            }
            else
            {
                icon.GetMountedWidget().Show( false );
            }
            
            if( !m_Entity.CanReleaseAttachment( item ) )
            {
                draggable = false;
            }
            
            if ((in_hands_condition || in_vicinity_condition) && can_be_removed)
            {
                icon.GetOutOfReachWidget().Show( false );
            }
            else
            {
                icon.GetOutOfReachWidget().Show( true );
                draggable = false;
            }
            
            if( draggable )
            {
                icon.GetRender().GetParent().SetFlags( WidgetFlags.DRAGGABLE );
            }
            else
            {
                icon.GetRender().GetParent().ClearFlags( WidgetFlags.DRAGGABLE );
            }
        }
    }

Перекрестные ссылки SlotsIcon::Clear(), SlotsIcon::ClearRemainSelected(), ClosableContainer::ContainerWithCargo(), ItemManager::GetDraggedItem(), SlotsIcon::GetEntity(), GetGame(), ItemManager::GetInstance(), SlotsIcon::GetMountedWidget(), SlotsIcon::GetOutOfReachWidget(), CGame::GetPlayer(), SlotsIcon::GetRadialIconPanel(), SlotsIcon::GetRender(), SlotsIcon::GetSlotID(), InventorySlots::GetSlotName(), SlotsIcon::Init(), AttachmentsOutOfReach::IsAttachmentReachable(), m_AttachmentCargos, m_AttachmentsContainer, m_Entity, SlotsIcon::Refresh(), Remove() и SlotsIcon::SetContainer().

Используется в RefreshAllSlots().