ChangeFilter()

void ScriptConsoleItemsTab::ChangeFilter ( TextListboxWidget widget, MultilineEditBoxWidget filterWidget, int categoryMask = -1, bool ignoreScope = false )

inlineprotected

См. определение в файле ScriptConsoleItemsTab.c строка 939

    {
        widget.ClearItems();
        
        TStringArray filters;
        TIntArray filterColors;
        
        string widgetText;
        filterWidget.GetText(widgetText);
        PrepareFilters(widgetText, filters, filterColors);
        
        map<string,int> itemsAndColors = new map<string,int>();
        map<string,ref TStringArray> itemsByFilters = new map<string,ref TStringArray>();
 
        TStringArray itemsArray = TStringArray();
        
        map<string, ref ScriptConsoleItem> items = m_Developer.GetItems();
        foreach (string itemName, ScriptConsoleItem itemData : items)
        {
            string displayName = "NO DISPLAY NAME";
            if (itemData.m_DisplayName != string.Empty)
                displayName = itemData.m_DisplayName;
            
            int scope = itemData.m_Scope;
            if (scope >= OBJECT_SCOPE || ignoreScope)
            {
                int categoryBit = itemData.m_CategoryMask;
                categoryBit = (1 << categoryBit);
                
                bool display = false;
                bool matchWithDisplayName = false;
                int color = 0;
                if (categoryBit & categoryMask)
                {
                    display = true;
                }
                else if ((!m_ConfigDebugProfile.GetMergeType() || categoryMask == 0) && filters.Count() > 0)
                {
                    string childNameLower = itemName;
                    childNameLower.ToLower();
                    string displayNameLower = displayName;
                    displayNameLower.ToLower();
                    
                    foreach (int indx, string filter : filters)
                    {
                        if (childNameLower.Contains(filter) || displayNameLower.Contains(filter))
                        {
                            display = false;
                            color = filterColors.Get(indx);
                            TStringArray arr = itemsByFilters.Get(filter);
                            if (!arr)
                            {
                                arr = new TStringArray();
                                itemsByFilters.Set(filter, arr);
                            }
 
                            arr.Insert(itemName + " - [" + displayName + "]");
                            itemsAndColors.Insert(itemName + " - [" + displayName + "]",color);
                            break;
                        }
                    }
                }
                else if (categoryMask == 0)
                {
                    display = true;
                }
 
                if (display)
                {
                    itemsArray.Insert(itemName + " - [" + displayName + "]");
                }
            }
        }
    
        if (itemsArray)
        {
            itemsArray.Sort();
            foreach (string it : itemsArray)
            {
                widget.AddItem(it, NULL, 0);
            }
        }
        
        if (filters)
        {
            if (m_FilterOrderReversed)
                filters.Invert();
            
            foreach (string f : filters)
            {
                TStringArray arr2 = itemsByFilters.Get(f);
                if (arr2)
                {
                    arr2.Sort();
                    foreach (string itm: arr2)
                    {
                        int row = widget.AddItem(itm, NULL, 0);
                        int clr = itemsAndColors.Get(itm);
                        if (clr)
                        {
                            widget.SetItemColor(row, 0, clr);
                        }
                    }
                }
            }
        }
    }

Перекрестные ссылки string::Contains(), ScriptConsoleTabBase::m_ConfigDebugProfile, m_Developer, m_FilterOrderReversed, OBJECT_SCOPE, PrepareFilters(), string::ToLower() и TStringArray.

Используется в ChangeFilterItems().