GetItemHealth()

int ActionTargetsCursor::GetItemHealth ( )

inlineprotected

См. определение в файле ActionTargetsCursor.c строка 853

    {
        int health = -1;
 
        if (m_Interact && !m_Interact.HasTarget())
        {
            return health;
        }
        
        Object tgObject = m_DisplayInteractTarget;
        if (!tgObject && m_Target)
        {
            tgObject = m_Target.GetObject();
        }
        
        if (tgObject)
        {
            Object tgParent = m_Target.GetParent();
            EntityAI targetEntity;
            
            //Return specific part health, even if display name is from parent
            if (!tgObject.IsAlive())
            {
                EntityAI ent;
                if (m_TargetItemFrozen && Class.CastTo(ent,tgObject) && (ent.IsAnimal() || ent.IsMan() || ent.IsZombie()))
                    health = -2; //frozen interaction later
                else
                    health = tgObject.GetHealthLevel();
                
                return health;
            }
            
            if (tgParent && (tgParent.IsItemBase() || tgParent.IsTransport()))
            {
                targetEntity = EntityAI.Cast(tgParent);
            }
            
            if (tgObject.IsItemBase() || tgObject.IsTransport())
            {
                targetEntity = EntityAI.Cast(tgObject);
            }
            
            if (targetEntity)
            {
                if (!targetEntity.IsDamageDestroyed())
                {
                    string zone = "";
                    array<string> selections = new array<string>();
                    
                    if (targetEntity.IsInherited(TentBase) && TentBase.Cast(targetEntity).GetState() != TentBase.PACKED)
                    {
                        //This is really specific to tents, as they use proxies. Hence object must be used
                        if (DamageSystem.GetDamageZoneFromComponentName(targetEntity, tgObject.GetActionComponentName(m_Target.GetComponentIndex(), LOD.NAME_FIRE), zone))
                        {
                            health = targetEntity.GetHealthLevel(zone);
                        }
                    }
                    else
                    {
                        //NOTE: relevant view geometry and view geometry selection names MUST match in order to get a valid damage zone
                        targetEntity.GetActionComponentNameList(m_Target.GetComponentIndex(), selections, LOD.NAME_VIEW);
                        
                        for (int s = 0; s < selections.Count(); s++)
                        {
                            if (DamageSystem.GetDamageZoneFromComponentName(targetEntity , selections[s], zone))
                            {
                                health = targetEntity.GetHealthLevel(zone);
                                break;
                            }
                        }
                    }
    
                    if (zone == "")
                        health = targetEntity.GetHealthLevel();
                }
            }
            else
            {
                health = tgObject.GetHealthLevel();
            }
        }
        
        return health;

Перекрестные ссылки Class::CastTo(), EntityAI::IsMan(), m_DisplayInteractTarget, m_Interact, m_Target, m_TargetItemFrozen, LOD::NAME_FIRE и LOD::NAME_VIEW.

Используется в PrepareCursorContent().